in reply to Re: minimum, maximum and average of a list of numbers at the same time
in thread minimum, maximum and average of a list of numbers at the same time

And with List::Util::reduce()... 

use List::Util qw/ reduce /;
sub min_max_avg {
  $res= reduce {
     my $r= ref $a ? $a : [($a) x 3];
     if ($b < $r->[0]) {
        $r->[0]= $b;
     } elsif ($b > $r->[1]) {
        $r->[1]= $b;
     }
     $r->[2]+=$b;
     $r
  } @_;

  return @$res[0,1], $res->[2] / @_;
}

[download]
---
$world=~s/war/peace/g

  • Comment on Re^2: minimum, maximum and average of a list of numbers at the same time
  • Download Code

Replies are listed 'Best First'.
Re^3: minimum, maximum and average of a list of numbers at the same time
by Limbic~Region (Chancellor) on Nov 10, 2005 at 13:45 UTC
    And if you want to go even more FP... 
    sub Gen_Stats {
    my $stat = {};
    my ($cnt, $max, $min, $tot);
    $stat->{ADD} = sub {
        $cnt += @_;
        for ( @_ ) {
            $tot += $_;
            $max = $_ if ! defined $max || $_ > $max;
            $min = $_ if ! defined $min || $_ < $min;
        }
    };
    $stat->{MAX} = sub { $max };
    $stat->{MIN} = sub { $min };
    $stat->{AVE} = sub { $cnt ? $tot / $cnt : undef };
    $stat->{TOT} = sub { $tot };
    $stat->{ADD}->( @_ );
    return $stat;
}
my $stat_info = Gen_Stats();
while ( <DATA> ) {
    chomp;
    $stat_info->{ADD}($_);
}
print join "\t", map { $_->() } @{$stat_info}{qw/MAX MIN AVE TOT/};

    [download]
    This code was borrowed from RFC: Tool::Box. I recommend using List::Util when and wherever possible. It has been part of the core since 5.007003 and uses XS when possible. The only real limitation I see with it is that all the items in the list must be known at once as I pointed out in How A Function Becomes Higher Order.

    Cheers - L~R

[reply]
[d/l]
Re^3: minimum, maximum and average of a list of numbers at the same time
by codeacrobat (Chaplain) on Nov 12, 2005 at 09:58 UTC
    Nice fast code, but does it return the right values? I checked with the orig mma routine, the my_mma routine and your reduce_mma routine. Using the same set of @nums, the results differ. 
    use Benchmark qw(:all :hireswallclock);

my @nums = map {rand} 1 .. 10000;
my $subs = {
             mma        => sub { my @r = min_max_avg(\@nums) },
             reduce_mma => sub { my @r = reduce_mma(\@nums)  },
             mymma      => sub { my @r = my_mma(\@nums)      }
           };


cmpthese(-1, $subs);

$count = 1000;
for my $sub (keys %$subs){
  $t = timeit($count, $subs->{$sub});
  print "$count loops of $sub:",timestr($t),"\n";
}
for my $sub (keys %$subs){
  print "$sub results:\n";
  print (join ' ', &{$subs->{$sub}} ,  "\n");
}

#####  Subs to test ######


__END__
$ perl benchmark.pl
              Rate        mma      mymma reduce_mma
mma         86.3/s         --       -49%      -100%
mymma        171/s        98%         --      -100%
reduce_mma 89229/s    103265%     52110%         --
1000 loops of reduce_mma:0.0114148 wallclock secs ( 0.00 usr +  0.00 s
+ys =  0.00 CPU)
1000 loops of mma:12.0897 wallclock secs (12.05 usr +  0.01 sys = 12.0
+6 CPU) @ 82.91/s (n=1000)
1000 loops of mymma:5.98583 wallclock secs ( 5.97 usr +  0.00 sys =  5
+.97 CPU) @ 167.56/s (n=1000)
reduce_mma results:
0.956444677504809 0.209810070551129 0.765697545177442
mma results:
0.000119859684559742 0.999992750475673 0.505291691541093
mymma results:
0.000119859684559742 0.999992750475673 0.505291691541093

    [download]
[reply]
[d/l]

      I can't replicate your results and you dont show the code you are using. I do recall that when i first posted my solution I had a mistake in the code, which I updated shortly afterwards. (Soon enough that i didnt bother with noting the update -- my bad i guess.) So if you downloaded that then yes, it isnt giving the correct results. But if you use the code that is in the thread now it should.

      ---
      $world=~s/war/peace/g

[reply]

In Section Seekers of Perl Wisdom