my %hash = (
   apple  => 'red',
   banana => 'yellow',
   orange => 'orange',
   lemon  => 'yellow',
);

my $value = 'yellow';

my @matching_keys = grep { $hash{$_} eq $value } keys %hash;

print("$_\n")
   foreach @matching_keys;
[download]

I think you want something like this:

my @keys = grep { $hash{$_} eq $value } keys %hash;
[download]

If you're just doing it once, use ikegami's approach. If you're doing it many times (where the term 'many' is intentionally vague) you may benefit from maintaining two hashes; one forward-lookup and one reverse-lookup, if that makes sense.

Bear in mind, however, that in a hash, while the keys are guaranteed to be unique, there is no guarantee that the values are unique. So there's a possibility that 'yellow' as a value could occur several times, each under different unique keys. This must be dealt with somehow when doing reverse-lookups. One way is to just make sure you "don't do that" (don't create hash entries that have equal values). And it happens that maintaining a reverse-lookup hash is an excellent way of keeping track of two-way uniqueness. ...but this is just a tangent...

my %hash          = ( a => 1, b => 2, c => 3 );
my %inverted_hash = reverse %hash;
[download]

use Data::Dumper;
print Dumper(\(%hash, %inverted_hash));

# Output:
# $VAR1 = {
#           'c' => 3,
#           'a' => 1,
#           'b' => 2
#         };
# $VAR2 = {
#           '1' => 'a',
#           '3' => 'c',
#           '2' => 'b'
#         };
[download]

%hash          = ( a => 1, b => 2, c => 2 );
%inverted_hash = reverse %hash;

print Dumper(\(%hash, %inverted_hash));

# Output:
# $VAR1 = {
#           'c' => 2,
#           'a' => 1,
#           'b' => 2
#         };
# $VAR2 = {
#           '1' => 'a',
#           '2' => 'c'
#         };
[download]

print "keys were lost during inversion\n"
    if keys %inverted_hash < keys %hash;
[download]

Cheers,
Tom

You could have a look at Tie::Hash::TwoWay, however, be sure to read the 'pecularities' listed.

Hope this helps, -gjb-

my %param;
foreach ( sort { $user_details{$a} cmp $user_details{$b} } keys %user_
+details ){
    #this next line will clobber $param{user_name} each time through. 
    #$param{user_name} = $user_details{$_};
    #do your stuff.

    print "the key is $_\n";
    print "the value is $user_details{$_}\n";
}
[download]

It's not clear from your description just what you want to try an achieve. Could you show us sample contents of %user_details and what you expect %param to contain following the loop?

As shown %param will contain one value (the "largest" according to the sort criteria) with the key user_name. I doubt that that is what you want.

Note also that the sort is futile in this case. It has no useful effect on the behaviour of the loop nor on how things are stored in %param.

#!/usr/local/bin/perl -w
use strict;

my %hash = (
   apple  => 'red',
   banana => 'yellow',
   orange => 'orange',
   lemon  => 'yellow',
);

my $value = 'yellow';

my %newhash = reverse %hash;

print $newhash{$value}, "\n";
[download]

That doesn't return all the keys if the values are not unique. According to the output either lemons or bananas aren't yellow.