Using previous match in the same matching regexp

cyberconte has asked for the wisdom of the Perl Monks concerning the following question:

This is a bit of an obfuscation question. Say you have this program:

my $string = '12 abcdefghijklmnopqrstuvwxyz';
my ($len) = ($string =~ /^(\d+)/;
my ($substring) = ($string =~ /^\d+ (.{$len})/);
print "$substring\n";
[download]

Is there a way to combine the two regexps? for example, something like

my ($len,$substring) = ($string =~ /^(\d+) (.{$1})/);
[download]

(except we know that doesn't work)? Having it all on one line in one regexp is the goal...

Thanks!

Comment on Using previous match in the same matching regexp Select or Download Code

Replies are listed 'Best First'.
Re: Using previous match in the same matching regexp by GrandFather (Saint) on Nov 16, 2005 at 22:48 UTC
`use warnings; use strict; my $string = '12 abcdefghijklmnopqrstuvwxyz'; $string =~ s/^(\d+) (.*)/substr $2, 0, $1/e; print "$string\n";` [download] Prints: `abcdefghijkl` [download] DWIM is Perl's answer to Gödel	[reply] [d/l] [select]
Re: Using previous match in the same matching regexp by Roy Johnson (Monsignor) on Nov 16, 2005 at 23:04 UTC
`my ($len,$substring) = ($string =~ /^(\d+) ((??{qr".{$1}"}))/);` [download] perlre explains the experimental postponed-regexp feature. Caution: Contents may have been coded under pressure.	[reply] [d/l]
Re^2: Using previous match in the same matching regexp by Anonymous Monk on Nov 16, 2005 at 23:17 UTC
Tightening up just a wee bit more... `my ($len,$substring) = ($string =~ /^(\d+) ((??{".{$1}"}))/);` [download]	[reply] [d/l]
Re: Using previous match in the same matching regexp by ikegami (Patriarch) on Nov 16, 2005 at 23:10 UTC
If you need a solution that doesn't clobber $string: `$substr = $string =~ /^(\d+) (.)/ && substr($2, 0, $1);` [download] If you need both $len and $substring: `($len, $substr) = $string =~ /^(\d+) (.)/ && ($1, substr($2, 0, $1));` [download]	[reply] [d/l] [select]
Re: Using previous match in the same matching regexp by japhy (Canon) on Nov 17, 2005 at 03:57 UTC
You could do: `$str =~ /^(\d+) /g and $str =~ /\G(.{$1})/;` [download] Jeff `japhy` Pinyan, P.L., P.M., P.O.D, X.S.: Perl, regex, and `perl` hacker How can we ever be the sold short or the cheated, we who for every service have long ago been overpaid? ~~ Meister Eckhart	[reply] [d/l]