Here's the code although it might not make much sense without context. The quantile function is passed a positive ordinal $r and a list of numbers @a. It returns the $r-th least number from the list if it would be sorted, with $r = 1 meaning to return the minimum of the list. If you want a median, pass $r = int((@a + 1)/2)

sub quantile {
        my($n, @a) = @_;
        my($q);
        @a < $n and
                return 9e9999;
        $q = quantile1($n, @a);
        if (1) { # DEBUG check postcondition
                my($nl, $nle);
                $nl = grep { $_ < $q } @a;
                $nle = grep { $_ <= $q } @a;
                $nl < $n && $n <= $nle or
                        die "postcondition failed";
        }
        $q;     
}

sub quantile1 {
        my($n, @a) = @_;
        my($c, $v, @l, @h);
        @a <= 1 and do {
                @a or
                        die "internal error: quantile1 called on empty
+ list, n=" . $n;
                return $a[0];
        };
        $c = @a[rand(@a)];
        for $v (@a) {
                if ($v < $c)
                        { push(@l, $v); }
                elsif ($c < $v)
                        { push(@h, $v); }
        }
        if ($n <= @l) {
                quantile1($n, @l);
        } elsif ($n > @a - @h) {
                quantile1($n - @a + @h, @h);
        } else {
                $c;
        }
}
[download]