From MJD’s file of good advice:

#11907 Looking for a compiler bug is the strategy of LAST resort. LAST resort.

#11943 Ah yes, and you are the first person to have noticed this bug since 1987. Sure.

As a first, second and third rule of thumb, always assume that the problem is in your code. All my mysterious bugs have always been my own bugs. As for what the problem is – you show so little code that noone will be able to do anything but guess. Post more code.

Makeshifts last the longest.

I've updated the code. Please re-review at your earliest conveinence. I'm afraid I was a tad hasty with my first post, as I was short on time. Sorry!

open my $ps, '-|', 'ps -eo pid,comm,args' or
  die "Can't run 'ps': $!\n";
[download]

my $output = do {
    open my $ps, '-|', 'ps -eo pid,comm,args' or
      die "Can't run 'ps': $!\n";
    local $/;
    <$ps>;
};
[download]

Please take the time and reduce your code to the bare minimum. The problem was completely unrelated to ps -ef, it was completely unrelated to the actual platform, it was completely unrelated to the weird inclusion of other scripts you did.

The problem can be reduced to the following code:

use strict;
my $PLATFORM = 'solaris';

foreach($PLATFORM) {
    (/solaris/ || /tru64/ || /linux/ || /aix/) and do {
        my $i=1;
        print "\$PLATFORM is '$PLATFORM'\n";

        open (PSTEST, $0);
        while (<PSTEST>){
                print "Line # ".$i."\n".$_;
                print "Platform now is '$PLATFORM'\n";
                $i++;
        };
        print "All done!\n";
        close PSTEST;

        print "Platform now is '$PLATFORM'\n";
    };
};
[download]

Please note the somewhat more instructive debugging output. Your problem stems from the spurious foreach ($PLATFORM) loop, which sets $_ as an alias to $PLATFORM and then clobbers it in the while loop. You can circumvent the problem by removing the spurious foreach loop which will execute only once anyway.

use strict;
my $PLATFORM = 'solaris';

#foreach($PLATFORM) {
  $_ = $PLATFORM;
    (/solaris/ || /tru64/ || /linux/ || /aix/) and do {
        my $i=1;
        print "\$PLATFORM is '$PLATFORM'\n";

        open (PSTEST, $0);
        while (<PSTEST>){
                print "Line # ".$i."\n".$_;
                print "Platform now is '$PLATFORM'\n";
                $i++;
        };
        print "All done!\n";
        close PSTEST;

        print "Platform now is '$PLATFORM'\n";
    };
#};
[download]

You should really really really rewrite the code as it is an optical mess and many of the code and employed techniques are quite bizarre.

Corion: Kudos for solving that one! However, the code is straight out of the Perl Cookbook for implementing a SWITCH construct. Any suggestions for replacing foreach?

Please reread my reply. I already posted how you can remove the foreach which is unnecessary. As an alternative, you could use a different variable than $_ in your inner while-loop:

        while (defined (my $line = <PSTEST>)){
                print "Line # ".$i."\n".$line;
                print "Platform now is '$PLATFORM'\n";
                $i++;
        };
[download]

How? Those will not let him capture output, will they?

Makeshifts last the longest.

Gadzooks!

Sorry Aristotle, not enough tea this morning. I seem to have somehow stupidly misinterpreted the whole question.

Knom, as Aristotle has so wisely said, you need to post your code, here is a quick example:


#!/usr/bin/perl
open (PSTEST, "/bin/ps  -eaf|");
$i=1;
while (<PSTEST>){
        print "Line # ".$i." ".$_;
        $i++;
}
close PSTEST;
[download]


Martin