Hi, your code is kind of long, and the wrong OS, for me to test; but I think you may be running into the common misconception that $thread->join forces a thread to terminate. It dosn't as the following code shows:

#!/usr/bin/perl
use warnings;
use strict;
use threads;

# join() does three things: it waits for a thread to exit, 
# cleans up after it, and returns any data the thread may 
# have produced.  

my $thr = threads->new(\&sub1);

my $return = $thr->join;

print "Thread returned @$return\n";

#hold for key input 
<>;
########################################################## 
sub sub1 {
  my  @values = ('1',2, 'ten');
  print "@values\n";

  while(1){sleep 1}

return \@values;
}
[download]

If you can't be sure that all your threads have reached the end of their code block, before you try to join them, you can force them to die with a shared variable. See how this minor modification will force the thread to return early, and thus be joinable.

#!/usr/bin/perl
use warnings;
use strict;
use threads;
use threads::shared;

# join() does three things: it waits for a thread to exit, 
# cleans up after it, and returns any data the thread may 
# have produced.  

my $die : shared = 0;

my $thr = threads->new(\&sub1);

#hold for key input 
<>;
$die=1;

my $return = $thr->join;

print "Thread returned @$return\n";

#hold for key input 
<>;
########################################################## 
sub sub1 {
  my  @values = ('1',2, 'ten');
  print "@values\n";

  while(1){
      sleep 1;
      if($die){return \@values }
      }

return \@values;
}
[download]