my $str = "Hello\n\t\n   World\n"; 
print $str; 
$str =~ s/\s+/ /g; 
print $str;
[download]

Output

Hello

   World
Hello World
[download]

Update: Please note this replaces all whitespace chars to a single space char. So if you have leading/trailing spaces please go with Your Mother's solution!

One way to normalize whitespace:

$foo = join ' ', split " ", $foo;
[download]

Something like this will do it.

my $str = "George         
     
                  Best
";

$str =~ s/(?<=[[:alpha:]])(?:\s\s+|[^\S ]+)(?=[[:alpha:]])/ /g;

print "'$str'\n";
[download]

(update: took off the pointless "s" from the s///) That might be more complicated (someone else might have a better one?) that than you need but I think it's good and will also fix things like--

It will not fix leading and trailing spaces. Just spacing between alpha characters.

I believe that:

s/(?<=[[:alpha:]])\s+(?=[[:alpha:]])/ /g;
[download]

Will have the same effect as your posted expression. Although it will replace a single space character between two letters with a single space character (essentially a no-op), because it is a simpler pattern will actually take less time to execute. Below I am posting a simple benchmark I used to test this theory. If I have missed something please enlighten me.

#!/usr/local/bin/perl -w
use strict;
use Benchmark;

my(@tests) = <DATA>;

timethese(400, {his => sub{ s/(?<=[[:alpha:]])(?:\s\s+|[^\S ]+)(?=[[:a
+lpha:]])/ /g foreach(@tests); },
                mine => sub{s/(?<=[[:alpha:]])\s+(?=[[:alpha:]])/ /g f
+oreach(@tests); }});


__DATA__
    A sting             with weird
A string without weird
                Another variety with            more wierd
Anotherthingwithnospaces
        something odd
soemthing normal


[me@mylinux]$ ./space.pl
Benchmark: timing 400 iterations of his, mine...
       his:  0 wallclock secs ( 0.07 usr +  0.00 sys =  0.07 CPU) @ 57
+14.29/s (n=400)
            (warning: too few iterations for a reliable count)
      mine:  0 wallclock secs ( 0.03 usr +  0.00 sys =  0.03 CPU) @ 13
+333.33/s (n=400)
            (warning: too few iterations for a reliable count)
[download]

---

They say that time changes things, but you actually have to change them yourself.

—Andy Warhol

You're right. I was trying to be overly correct I think in avoiding replacing " " with " "; it slows down the works considerably so it's not the way to go for this.

To retain external white space while collapsing internal white space:

use strict;
use warnings;

my $str = "  Hello\n\t\n   World  \n";
print ">$str<\n";
$str =~ s/\b\s+\b/ /g;
print ">$str<\n";
[download]

Prints:

>  Hello
    
   World  
<
>  Hello World  
<
[download]