# first of all, use the strictures: 
use strict;
use warnings;

# second of all, pare the question down to its bare essense,
# and leave al other extraneous stuff out.
my @jobs = ( sub {print "a\n"},
          sub {print "b\n"}
        );

print "one way to call anonymous subs, deferencing with the arrow:\n";
for my $job (@jobs) {
    $job->();
}
# hope this helps!

print "another way, deferencing with the & sigil:\n";
for my $job (@jobs) {
    &$job();
}

print "same thing, deferencing with explicit braces:\n";
for my $job (@jobs) {
    &{$job}();
}
[download]

You can call a subroutine whose name is stored in an array element (or, indeed, any scalar variable) like this:

#!/usr/bin/perl

#use strict;
use warnings;

sub test {
  print "pass\n";
}

my @subs = ('test');

$subs[0]();
[download]

However, note that I had to comment out the "use strict" in my code. This is generally a sign that you are doing something slightly dangerous. In this case you are using a technique called a "symbolic reference" which is really not recommended. The recommended way to do this is to store a reference to the subroutine instead of the subroutine's name. That looks like this:

#!/usr/bin/perl

use strict;
use warnings;

sub test {
  print "pass\n";
}

my @subs = (\&test);

$subs[0]->();
[download]

Notice that in this case we are able to uncomment "use strict".

@jobIds = $jobs->get_jobIds($ARGV[0]);
[download]

@jobIds = $jobs->$args_input[2]($args_input[3]);
[download]

Oh. Ok, so your problem is in calling a method.

Then the solution is get the name of the method into a scalar variable before trying to call it.

#!/usr/bin/perl

use strict;
use warnings;

package Foo;

sub new {
  bless {}, shift;
}

sub test {
  print "pass\n";
}

package main;

my @subs = ('test');

my $foo = Foo->new;

my $method = $subs[0];
$foo->$method;
[download]

--
<http://dave.org.uk>

"The first rule of Perl club is you do not talk about Perl club."
-- Chip Salzenberg

my $method = $subs[0];
$foo->$method;
[download]

Or, if you're in the mood for obfuscation:

$foo->${ \$subs[0] };
[download]

Thats really gr8 stuff!!!!!!!!!!!!!!

For calling methods from array variables. cool.

Thanks a lot.

rsennat