Welcome to Perl!

First, rather than rewriting your looping and logic, let's just cover the expression for checking alternatives and I think you can work out the rest as part of your own experimentation. You can do it like this (parens added for clarity):

($input ne 'good') && ($input ne 'bad') && ($input ne 'iffy')
[download]

You may not be ready for regular expressions quite yet, but they provide another approach to matching alternatives

! ( $input =~ /good|bad|iffy/ )
[download]

You can read that =~ bit as "input matches good or bad or iffy" in the way we idiomatically mean that in English. Negating that can also be done all in one as this:

$input !~ /good|bad|iffy/
[download]

Best of luck

Thank you for making me feel welcome!
"Es gibt mehr zu Leben als Bücher, kennen Sie. Aber nicht viel mehr " -(Der Smiths)

elsif (
  $input ne 'good' and
  $input ne 'bad' and
  $input ne 'iffy'
){
next;
}
[download]

elsif (
 $input !~ /good|bad|iffy/
){
next;
}
[download]

my %lookup = (
  good => undef,
  bad  => undef,
  iffy => undef,
);
# and then within your loop
next unless exists $lookup{$input};
[download]

update: added a missing brace
update 2: changed =~ to !~ in second snippet

If you are looking to match exact words, then you might consider solving this problem with a hash instead:

my %moods = (
    good => "Glad you are doing well!\n",
    bad  => "Oi, that's not good to hear!\n",
    iffy => "At least you're undecided...still hope after all.\n",
);

while (1) 
{
    print "Are you having/had a good, bad, or iffy day $name?: ";
    chomp( my $input = <STDIN> );
    
    # assuming case-insensitive:
    next unless exists $moods{ lc( $input ) };

    print $moods{ lc( $input ) };
    last;
}
[download]

update: wfsp beat me to it.

    $input ne 'good' && $input ne 'bad' && $input ne 'iffy'
[download]

However, in your example, you don't need this test at all. You've already covered the cases for 'good', 'bad' and 'iffy', so by the time you get here, you already know $input isn't containing any of them. Write your chain as:

if    ($input eq 'good') {print "..."}
elsif ($input eq 'bad')  {print "..."}
elsif ($input eq 'iffy') {print "..."}
else {next}
last;
[download]

Finally, your loop stinks. You have a while loop whose guard is always true, but then inside you read unconditionally from standard input. What if there's nothing more to read?

I would write that as:

print "Are you having/had a good, bad, or iffy day $name?: ";
while (my $input = <>) {
    chomp $input;
    if    ($input eq 'good') {print "..."; last}
    elsif ($input eq 'bad')  {print "..."; last}
    elsif ($input eq 'iffy') {print "..."; last}
    print "Are you having/had a good, bad, or iffy day $name?: ";
}
[download]

Purists may object to the duplication of the code - the printing of the prompt happens twice. If so, one could use IO::Prompt or write something like:

while (do {print "...."; defined (my $input = <>)}) {
    if    (...) {...; last}
    elsif (...) {...; last}
    elsif (...) {...; last}
}
[download]

my @acceptable = ('good', 'bad', 'iffy');
while(<>) {
    chomp;
    my $input = $_;
    foreach (@acceptable) {
        next unless  $_ eq $input;
        print "You are feeling $_!";
        undef $input;
        last;
    }
    unless( $input) {
        print "You didn't give an acceptable answer! Try again:\n";
    }
}
[download]