my $file = $mod;
$file =~ s{::}{/}g;
$file .= '.pm';
eval {
   require $file;
};
die("Unable to load $mod: $@\n")
   if $@;
[download]

should do what you want.

Note that it executes at run-time (while use executes at compile-time), but that's probably fine. Wrap the code in a BEGIN { } block if you need to execute this at compile-time.

Note that it doesn't import symbols, but that's probably a good thing for dynamically loaded modules. Add $mod->import if $mod->can('import'); if you need to import symbols.

Update: PodMaster suggested that I provide these links: use, require.

For a prepackaged approach, it might be worth considering UNIVERSAL::require. Its synopsis:

  # This only needs to be said once in your program.
  require UNIVERSAL::require;

  # Same as "require Some::Module"
  my $module = 'Some::Module';
  $module->require or die $@;

  # Same as "use Some::Module"
  BEGIN { $module->use or die $@ }
[download]

-xdg

Code written by xdg and posted on PerlMonks is public domain. It is provided as is with no warranties, express or implied, of any kind. Posted code may not have been tested. Use of posted code is at your own risk.

$mod->import if $mod->can('import');

No can() check needed; if there's no import, $mod->import() is silently a noop (even if there is an AUTOLOAD!).