See also Array::Unique

One way

perl> @big = qw(a b c d e f g h i);;
perl> @small = qw(f c d g);;
perl> undef @found{ @small };;

perl> @wanted = ( @small, grep{ !exists $found{ $_ } } @big );;

perl> print @wanted;;
f c d g a b e h i
[download]

The above assumes there are no dups in @big:

my @big = qw( a b c d e f g h i a );
my @small = qw( f c d g );

my %found;
undef @found{@small};
my @wanted = ( @small, grep{ !exists $found{ $_ } } @big );

print("@wanted\n");
# f c d g a b e h i a
[download]

The OP's version removed dups fom @big, and so does the following version:

my @big = qw( a b c d e f g h i a );
my @small = qw( f c d g );

my %found;
$found{$_}++ foreach @small;
my @wanted = ( @small, grep{ !($found{$_}++) } @big );

print("@wanted\n");
# f c d g a b e h i
[download]

Agreed. Your version can be simplified a little though.

my @big = qw( a b c d e f g h i a );
my @small = qw(f c d g c);
my %seen;
my @wanted = grep{ !$seen{ $_ }++ } @small, @big;

print "@wanted";
f c d g a b e h i
[download]

---

Examine what is said, not who speaks -- Silence betokens consent -- Love the truth but pardon error.

Lingua non convalesco, consenesco et abolesco. -- Rule 1 has a caveat! -- Who broke the cabal?

"Science is about questioning the status quo. Questioning authority".

In the absence of evidence, opinion is indistinguishable from prejudice.

Don't forget Super Search. You might want to seek out information on modules such as Tie::Hash. A node that may help: Preserving order for nested hashes using Tie::IxHash.

HTH,

my @big = qw(a b c d e f g h i);
my @kw= qw(f c d g); 
my %small = map {$_=>undef} @kw;

exists $small{$_} or push @kw,$_ for @big; 

# or, Alternatively,
#    push @kw,grep {!exists$small{$_}}  @big;

print qq(@kw\n);

-- Output --
f c d g a b e h i
[download]

use strict;
use warnings;

my @big = qw(a b c d e f g h i);
my @small = qw(f c d g);
my %small; $small{$_}=1 for @small;

my @keys_wanted = @small;
foreach ( @big ) {
    push @keys_wanted, $_ unless $small{$_};
}

print "@keys_wanted";
[download]