You might want to look at Test::Class and the section on "Extending Test Classes by Inheritance".

For a more manual approach, what I've often found helpful when I feel like I'm needing identical tests is just creating my testing functions in a helper module that takes an object to be tested (or even just a class name) and a prefix for the test label.

# file: t/helper.pm
package t::helper;

@EXPORT = qw( run_all_tests );

use strict;
use warnings;
use base 'Exporter';
use Test::More;

sub run_all_tests {
    my ($obj, $prefix) = @_;

    diag "Starting tests for $prefix";
    
    isa_ok( $obj, "Parent::Class", "$prefix: object isa Parent::Class"
+ );

    ok( $obj->true(), "$prefix: true() is true" );

    # more tests ...
}

1;
[download]

# file: t/001.t
use Test::More 'no_plan';
use t::helper;

my @cases = ( 
    Parent::Class->new(), 
    Sub::Class->new(),
);

for my $o ( @objs ) {
    run_all_tests( $o, ref $o );
}
[download]

Does that do what you were looking for? Or did you mean something different by "comprehensive output"?

I've already met a similar problem. See this perl bug report where I made all tests have every parameter in their name.

Also see the diag function in Test::More.

This link requires a username/password, if you don't have an account, use guest/guest to view.

First off - has anyone done this?

Yup. One of the motivations behind Test::Class was solving exactly this sort of problem. Getting test running is pretty simple.

# create a base class that contains your generic tests
{   package BaseClass::Test;
    use base qw( Test::Class );
    use Test::More;
    
    sub class_under_test {
        my $self = shift;
        my $class = ref $self;
        $class =~ s/::Test$//;
        return $class;
    }
    
    my $o;
    
    sub create : Test( setup => 1 ) {
        my $self = shift;
        my $class = $self->class_under_test;
        $o = $class->new;
        isa_ok $o, $class;
    }
    
    sub answer : Test {
        is $o->answer, 42;
    }   
    
    # because we don't want our abstract test class to run
    __PACKAGE__->SKIP_CLASS( 1 ); 
}

my @classes_to_test = qw( Foo Bar Ni );

# make a bunch of subclasses of our base test class
eval "package ${_}::Test; use base 'BaseClass::Test'"
    foreach @classes_to_test;

# run everything
Test::Class->runtests;

__END__
# will output something like

1..6
ok 1 - The object isa Bar
ok 2 - answer
ok 3 - The object isa Ni
not ok 4 - answer
#   Failed test 'answer'
#   in foo.pl at line 44.
#          got: 'infinity'
#     expected: '42'
ok 5 - The object isa Foo
ok 6 - answer
# Looks like you failed 1 test of 6.
[download]

Where it currently falls down is the test reporting. It's currently a little tricky to see which particular subclass failed a test. You either have to add it in to the test description explicitly, or set TEST_VERBOSE - which is a little too verbose. Making this easier is on the to do list.