in reply to Re: breaking an array into nearly equal parts
in thread breaking an array into nearly equal parts

You're right - and the pattern holds true. A positive integer can either be exactly divisible by three, have a remainder of 1, or a remainder of 2. Your idea is probably one of the simplest.

  • Comment on Re^2: breaking an array into nearly equal parts

Replies are listed 'Best First'.
Re^3: breaking an array into nearly equal parts
by Roy Johnson (Monsignor) on Dec 14, 2005 at 18:32 UTC
    It is quite simple. Here's an implementation. The apportion figures out chunk sizes; multi_slice returns slices of those sizes. The for block runs a few examples. 
    sub apportion {
  my ($elements, $pieces) = @_;
  my $small_chunk = int $elements / $pieces;
  my $oversized_count = $elements % $pieces;
  ((1 + $small_chunk) x ($oversized_count), ($small_chunk) x ($pieces 
+- $oversized_count));
}

sub multi_slice {
  my ($aref, @chunk_sizes) = @_;
  my $hi_i = -1;
  map {
    my $lo_i = $hi_i + 1;
    $hi_i += $_;
    [@$aref[$lo_i..$hi_i]]
  } @chunk_sizes;
}

for my $try ([16,3], [17,4], [19,3]) {
  print "$try->[0] elements into $try->[1] pieces:\n";
  print "Sizes: ", join(', ', apportion(@$try)), "\n";
  print "@$_\n" for multi_slice([1..$try->[0]], apportion(@$try));
}

    [download]
    Caution: Contents may have been coded under pressure.
[reply]
[d/l]
[select]

In Section Seekers of Perl Wisdom