Hi vnpenguin,

Use each_array method in List::MoreUtils module.

use strict;
use List::MoreUtils qw(each_array);
undef $/;
my $text=<DATA>;

my $a=$1 if $text=~m#v_x \{([^\}]+)\}#;
my @a=split( "\n", $a );

my $b=$1 if $text=~m#v_y \{([^\}]+)\}#;
my @b=split( "\n", $b );

my $c=$1 if $text=~m#v_z \{([^\}]+)\}#;
my @c=split( "\n", $c );

my $ea = each_array(@a, @b, @c);
while ( my ($a, $b, $c) = $ea->() )
{
    print "$a\t$b\t$c\n";
}


__DATA__
v_x {
x1
x2
x3
x4
x5
x6
x7
x8
}
v_y {
y1
y2
y3
y4
y5
}
v_z {
z1
z2
z3
z4
z5
z6
}
[download]

OUTPUT:

x1      y1      z1
x2      y2      z2
x3      y3      z3
x4      y4      z4
x5      y5      z5
x6              z6
x7
x8
[download]

Thanks,
Gopal.R

Hi Gopal.R, Thank you so much for your reply. Regards,

use strict ;
use warnings ; 
my $vec ;
my %rez ; 
my $cpt = 0 ;
my $maxcpt = 0;

foreach my $item  (<DATA>) {

    chomp $item ; 

    next if $item =~ m/^}$/ ;
    
    if ( $item =~ m/^v_(.*) {/ ) {
    
        $vec = $1 ; 
        $maxcpt = $cpt if $cpt > $maxcpt ;
        $cpt = 0 ; 
            
    } else { 
    
        $rez{$vec}[$cpt] = $item  ;
        $cpt ++ ;
        
    }

}


foreach my $cpt (0..$maxcpt) {

    foreach my $vec ( keys %rez ) {
    
        if (defined $rez{$vec}[$cpt]) { 
        
            print $rez{$vec}[$cpt], "\t"

        } else { print "\t" } ; 

    }
    
    print "\n" 

}



__DATA__ 
v_x {
x1
x2
x3
x4
x5
x6
x7
x8
}
v_y {
y1
y2
y3
y4
y5
}
v_z {
z1
z2
z3
z4
z5
z6
}
[download]

Thank you very much, Regards,

use strict;
use warnings; 
my ($x, $y) = (0,0); #table axes, x is horizontal, y is vertical
my ($max_x, $max_y) = (0,0);
my $table ; #hash of arrays

while (<DATA>) {
    chomp; 
    #print "$_\n";
    if (  $_ =~ m/^v_(.*)\s*{/ ) {
        $y = 0;
    } elsif ( $_ =~ m/^}$/ ) {
        $max_x = $x if $x++ > $max_x;
    } else {
        $table->[$x]->[$y] = $_;
        $max_y = $y if $y++ > $max_y;
    } 
}

for my $y (0..$max_y) {
    for my $x (0..$max_x) {
        my $item = defined( $table->[$x]->[$y] ) ? $table->[$x]->[$y] 
+: '  ';
        print "$item ";
    }
    print "\n";
}

__DATA__ 
v_x {
x1
x2
x3
x4
x5
x6
x7
x8
}
v_y {
y1
y2
y3
y4
y5
}
v_z {
z1
z2
z3
z4
z5
z6
}
[download]

Hi tphyahoo, There is an extra empty ligne in output :) So maybe:

for my $y (0..$max_y-1) {
...
}
[download]

Thank you !

This problem is interesting (i.e. fun) because it has two parts, each of which requires some thought: parsing the input data and formatting the output.
Here's my solution:

use strict;

my @keys; # just to preserve order
my %data;

local $_ = do { local $/; <DATA> };
while ( /(v_\w) {\n([^}]*)\n}/g )
{
    push @keys, $1;
    $data{$1} = [ split /\n/, $2 ];
}

my $row = 0;
while (1)
{
    my @v = map { $data{$_}[$row] } @keys;
    last unless grep defined($_), @v;
    printf "%-3s", $_ for @v;
    print "\n";
    $row++;
}
[download]

use strict;
use warnings;
$\ = $/;
while (<DATA>) {
    chomp;
    my $v= ((/{/ .. /}/) || 0);
    if ($v==1) {
        @_=();
    } elsif ($v=~/E0$/) {
        print "@_";
    } else {
        push @_, $_;
    }
}
[download]

You can use the above with

push @collect, [@_];

instead of the print statement (declare @collect prior to the loop) and use any suggested method here or in the other mentioned thread to transpose and output that AoA.

use strict;
undef $/;
my $data = <DATA>;
my (%hash, @chars) ;
my $count = 0;

foreach (split("\n", $data)) {
push @chars , $1 if $_ =~  m/^v_((.*)) {/ ; # Thanks Anonymous Monk-- 
}

foreach  (@chars) {
   @{$hash{$_}} = split( "\n", $1) if $data =~ m#v_$_ \{([^\}]+)\}#;
   $count = ($count > @{$hash{$_}}) ? $count : @{$hash{$_}} ;
}

for  my $c (0..$count) {
      print ${@{$hash{$_}}}[$c] ."\t" foreach ( @chars );
      print "\n" ;
}
[download]

Why do you split $1 on "{"? $1 does never contain a "{". Or am I mistaken?