Some mobile phones provide a predictive function when writing text messages so that when you type 'gdjjm' you get the more likely match 'hello'.

Recently I noticed that 'kiss' maps to the same keys as 'lips' and so I wrote the following short program to see if there were any other interesting matches. These are refered to as textonyms apparently.

Run it against a word list as follows:

    perl mobile.pl /usr/dict/words
[download]

Here are a few of the other interesting collisions:

    ANSI   Borg
    darn   farm
    book   cool
    home   good
    rifle  shelf
    babies caches
    autumn button
    Jaeger ladies
[download]

And here is the program:

    #!/usr/bin/perl -wl

    use strict;

    my $min =  3;
    my %words;

    while (<>) {
        chomp;
        next unless length > $min;
        my $index = lc $_;

           $index =~ tr[abc def ghi jkl mno pqrs tuv wxyz]
                       [222 333 444 555 666 7777 888 9999];

        push @{$words{$index}}, $_;
    }


    for my $index (sort {$a <=> $b} keys %words) {
        my @words = sort @{$words{$index}};
        next unless @words > 1;
        print for '', @words;
    }

    __END__
[download]