Having run your code, it's not entiely clear to me exactly what you want as output. If you want the entire body of the text with the keyword highlighted, that's easy. If you want from the first to last match plus some context on either end that's also easy, but in both cases you end up extracting most if not all of the article if there are two occurrances of the match far apart.

Alternatively, if you want a shortish snippet, (5 or 10 words tops), for each match, but with any snippets of the target length that include two or more matches merged, then this seems to work for that limited set of cases I've tried:

P:\test>517393-3 -N=1 got
...I've <<got>> a
question that's <<got>> me...


P:\test>517393-3 -N=3 got
...me, and I've <<got>> a
question that's <<got>> me stumped. Here's...


P:\test>517393-3 -N=5 got
...spot for me, and I've <<got>> a
question that's <<got>> me stumped. Here's the problem...


P:\test>517393-3 -N=3 and
...spot for me, <<and>> I've got a...

...capture the word <<and>> X number of words before <<and>> after it
while...

...than one term <<and>> they overlap, the...


P:\test>517393-3 -N=3 the
...me stumped. Here's <<the>> problem I'm trying...

...do is capture <<the>> word and X...

...it
while tagging <<the>> matching word in <<the>> captured text. My...

...and they overlap, <<the>> nth term will...

...a regex even <<the>> best
way to...


P:\test>517393-3 -N=3 of
...somwhat large articles <<of>> text (returned from...

...and X number <<of>> words before and...


P:\test>517393-3 -N=10 of
...problem I'm trying to solve.
I have somwhat large articles <<of>> text (returned from a search), wh
+at I'd
like to do...

...like to do is capture the word and X number <<of>> words before and
+ after it
while tagging the matching word...
[download]

Maybe that's useful, but if not it was an interesting exercise :)

#! perl -slw
use strict;

our $N ||= 3;

my $word = $ARGV[0] or die "No search term";

my $text = do{ local $/; <DATA> };

my $re_word = qr[
    (?<=\s)
    $word
    [[:punct:]]*
    (?=\s)
]x;

$text =~ s[
    (
        (?: \S+ \s+ ){0,$N}
        $re_word
        (?: .{0,60} $re_word )?
        (?= ( (?: \s+ \S+ ){0,$N} )  )
    )
][
    my $extract = "...$1$2...";
    $extract =~ s[ ( \s ) ( $word ) ( [[:punct:]]*\s ) ][$1<<$2>>$3]gx
+;
    print $extract, $/;
]gsex;

__END__
Regular expressions have always been a weak spot for me, and I've got 
+a
question that's got me stumped. Here's the problem I'm trying to solve
+.
I have somwhat large articles of text (returned from a search), what I
+'d
like to do is capture the word and X number of words before and after 
+it
while tagging the matching word in the captured text. My inital though
+t
was to try something like this. The problem I have is that if there is
more than one term and they overlap, the nth term will not be annotate
+d.
So my next thought is lookahead/lookbehind, but they don't capture.
Is there a way to do this with a single regex? Is a regex even the bes
+t
way to do this? Thanks, -Lee
[download]