The following works for the range of formats you have given.

use strict;
use warnings;

my %months =
  (
  january =>  'jan',
  february => 'feb',
  march =>    'mar',
  april =>    'apr',
  may =>      'may',
  june =>     'jun',
  july =>     'jul',
  august =>   'aug',
  september =>'sep',
  october =>  'oct',
  november => 'nov',
  december => 'dec',
  );

my %monthCvt =
  (
  jan => 1, feb => 2, mar => 3, apr => 4, may => 5, jun => 6,
  jul => 7, aug => 8, sep => 9, oct => 10, nov => 11, dec => 12,
  );

while (<DATA>)
  {
  chomp;
  $_ = lc $_;

  # Strip leading spaces
  s/\s*//;

  # Normalize month
  s/([a-z]+)/$months{$1} || $1/e;

  # Normalize punctuation
  s|[ -/,.\\]+| |g;

  # Normalize order: month day year
  s|^(\d+)\s([a-z]+)|$2 $1|;

  # Extract fields
  my ($month, $day, $year) = /(\w+) (\d+) (\d+)/;

  # Month to numeric form if required
  $month = $monthCvt{$month} if $month !~ /\d/;

  print "$month/$day/$year\n";
  }

__DATA__
 Sep 29 2005
 Jun 30, 2003
 December 15 2005
 December 31, 2004
 06-Dec-2005
 10-19-2005
[download]

Prints:

9/29/2005
6/30/2003
12/15/2005
12/31/2004
12/06/2005
10/19/2005
[download]

Further to salva's excellent answer, there is also Date::Calc which is less resource-intensive than Date::Manip and almost as flexible.

Also, just as a note, if you have formats that alternately specify dd-mm-yyyy and mm-dd-yyyy in all numbers you won't be able to reliably parse those dates because there is no way for the parser to tell them apart in many cases (your example doesn't give that, but it does give mm-dd-yyy and dd-month-yyyy, so I thought I'd flag this).

And yes, I did see your note about not wanting to use external modules....

...but, for the sake of the exercise, and just to prove that it can be done - here it is extending upon my earlier reply using Regexp::Common::time :)

#!/usr/bin/perl -w
use strict;
use Regexp::Common qw(time);

while (<DATA>) {
    print if ($_ =~ $RE{time}{strftime}{-pat =>
        '((%B|%b) %d|%d-%b|%m-%d)[\s\-,]+%Y'});
}

__DATA__
 Sep 29 2005
some stuff
 Jun 30, 2003
some more stuff
 December 15 2005
not a date
 December 31, 2004
 06-Dec-2005
 10-19-2005
[download]

Which gives:

 Sep 29 2005
 Jun 30, 2003
 December 15 2005
 December 31, 2004
 06-Dec-2005
 10-19-2005
[download]

Cheers,
Darren :)

use Date::Parse qw(strptime);
for (<DATA>) {
    my @date =  (strptime($_))[4,3,5];
    ++$date[0];
    $date[2] += 1900;
    print join('/' => @date) . $/;
}
[download]