%searchlist = map { $_ => 1 } @searchlist;

open(IN,"test.txt");
while (<IN>) {
  chomp;
  if ( $searchlist{$_} ) {print "Match Found"}
}
[download]

Your suggestion would find any matching item on a line by itself. It is not clear from the OP whether the file to be searched is laid out that way. If (as I suspect) it's paragraphs, then it would need to be broken down into words to be checked one-by-one, or they'd need to use your Regex::Assemble solution.

---

Caution: Contents may have been coded under pressure.

Aside from note by Roy Johnson, I would change

if ( $searchlist{$_} ) {print "Match Found"}

to

if ( exists $searchlist{$_} ) {print "Match Found"}

since your test would add a entry to the hash on each word which isn't there.
Update: This is wrong, see reply.

That's wrong. Just looking up a hash key does not autovivfy that key. Consider

my %h = ();

print "found" if $h{somekey};

print %h;
[download]

which prints nothing. The key "somekey" is not autovivied.


holli, /regexed monk/

my @patterns;
foreach my $pattern (`ls`) {
    chomp $pattern;
    push @patterns, qr/\Q$pattern\E/;
}

open(IN,"test.txt") or die "Can't open test.txt: $!\n";
while(my $line = <IN>) {
    chomp $line;
    foreach my $pattern (@patterns) {
        print "Match found\n" if $line =~ $pattern;
    }
}
[download]

Or even

    print "mf" if grep { $line =~ $_ } @patterns;
[download]

instead of

    foreach my $pattern (@patterns) {
        print "Match found\n" if $line =~ $pattern;
    }
[download]



holli, /regexed monk/

Additionally, why use ls?

opendir(my $dh, '.')
  or die("Unable to list directory: $!\n");

my @searchlist = readdir($dh);
[download]

or

opendir(my $dh, '.')
  or die("Unable to list directory: $!\n");

while (defined(my $file = readdir($dh))) {
   ...
}
[download]

Combined with sachmet's solution:

opendir(my $dh, '.')
  or die("Unable to list directory: $!\n");

my @patterns = map { qr/\Q$_\E/ } 
               grep { /^\.\.?$/ }
               readdir($dh);

open(my $fh_in, 'test.txt')
   or die("Unable to open input file test.txt: $!\n");

while (my $line = <$fh_in>) {
   chomp $line;
   foreach my $pattern (@patterns) {
      print("Match found\n") if $line =~ $pattern;
   }
}
[download]

Combined with holli's solution:

opendir(my $dh, '.')
  or die("Unable to list directory: $!\n");

my %searchlist = map { $_ => 1 }
                 grep { /^\.\.?$/ }
                 readdir($dh);

open(my $fh_in, 'test.txt')
   or die("Unable to open input file test.txt: $!\n");

while (my $line = <$fh_in>) {
   chomp $line;
   print("Match found\n") if $searchlist{$line};
}
[download]

Update: Fixed copy & paste error map { qr/\Q$pattern\E/ } => map { qr/\Q$_\E/ }.

One subtle difference between your use of readdir and the OP's use of ls is that the latter will not list dot-files (e.g., .profile) by default. Conveniently, glob('*') mimics that behavior and shortens the necessary code:

my %searchlist = map {$_ => 1} glob('*');
[download]

---

Caution: Contents may have been coded under pressure.

Aye. The non-glob alternative would be to change
grep { /^\.\.?$/ }
to
grep { /^\./ }

perl -e 'chomp(@l=(<*>));open(FH,"<test.txt") or die;while(<FH>){for $
+w(@l){/\b$w\b/ ? print: next}}'
[download]