A few quick comments. This code:

    if ($oids{ifName}{$a} =~ /\//) {
        @a = split(/\//, $oids{ifName}{$a});
        @b = split(/\//, $oids{ifName}{$b});
    }
    else {
        @a = $oids{ifName}{$a};
        @b = $oids{ifName}{$b};
    }
[download]

Can be replaced with simply:

    @a = split m{/}, $oids{ifName}{$a};
    @b = split m{/}, $oids{ifName}{$b};
[download]

And this code:

    if ($a[0] =~ /[A-Za-z]/) {
        $a[0] ne $b[0] ? $a[0] cmp $b[0] : ($a[1] <=> $b[1] ? $a[1] <=
+> 
+$b[1] : $a[2] <=> $b[2]);
    } else {
        $a[0] != $b[0] ? $a[0] <=> $b[0] : ($a[1] <=> $b[1] ? $a[1] <=
+> 
+$b[1] : $a[2] <=> $b[2]);
    }
[download]

Can be replaced with:

    if ($a[0] =~ /[A-Za-z]/) {
        $a[0] cmp $b[0] || $a[1] <=> $b[1];
    }
    else {
        $a[0] <=> $b[0] || $a[1] <=> $b[1];
    }
[download]

I'm sure there are other refinements, but these ones stood out to me immediately.

Update: perhaps the 2nd can even be simplified to:

    $a[0] <=> $b[0] || $a[0] cmp $b[0] || $a[1] <=> $b[1];
[download]

I think so, but I haven't tested to make sure.

Another update: I noticed I left out the 3rd level comparison, but hopefully it should be obvious how to add it in. :-)

Oooh, thanks! I like the reduction of the array assignments. (Reducing my code to elegant/minimal pieces is proving a challenge.)

(Not annoying at all, ty!)

Well, #3 is pretty easy to answer.

# given the string value in $_ ...

my @v = split m#/#;
unshift @v, shift(@v) =~ /^(.*?)(\d*)$/;
[download]

For values that don't have any letters at the beginning, the first element of @v will be an empty string.

From there, you can easily create a sort key, using (for example)

    sprintf "%-4s%3d%3d%3d", @v;
[download]

  map { $_->[1] }
  sort { $_->[0] cmp $_->[1] }
  map {
    my @v = split m#/#;
    unshift @v, shift(@v) =~ /^(.*?)(\d*)$/;
    no warnings; # in case @v has less than 4 elements
    [ sprintf( "%-4s%3d%3d%3d", @v ), $_ ]
  }
[download]

This is separate enough from my previous reply that I thought I'd reply again. Hopefully I don't get too annoying. ;-)

The code above gives me my desired result with my existing data set. In case that changes in the future, I'm trying to figure out how to split "Fa10/0/1" into [Fa, 10, 0, 1] but all my ideas involve substrings & splits & freaky array manipulations and quickly get very ugly. Ideas?

    @a = $a =~ /( [[:alpha:]]+ | [[:digit:]]+ )/gx;
    @b = $b =~ /( [[:alpha:]]+ | [[:digit:]]+ )/gx;
[download]

Sometimes its worth it to just turn off uninitialized warnings:

foreach my $hash (@hash) {
  no warnings 'uninitialized';
  print "$_ => $hash->{$_}\n" for
    map { $_->[0] }
    sort {
           $a->[1] cmp $b->[1]
        || $a->[2] <=> $b->[2]
        || $a->[3] <=> $b->[3]
        || $a->[4] <=> $b->[4]
    }
    map { [ $_, $hash->{$_}=~m!^(?:([a-z]+)(\d+)/)?(?:(\d+)/)?(\d+)$!i
+ ] }
    keys %$hash;
    print "-","\n";
}
__END__
2 => Gi1/0/0
1 => Gi1/0/1
3 => Gi1/1/1
4 => Gi2/0/0
5 => Gi2/0/1
-
1 => 1
2 => 2
3 => 3
4 => 4
5 => 5
-
4 => 1/1
5 => 1/2
1 => 2/1
2 => 4/5
3 => 15/1
-
1 => Fa0/1
2 => Fa0/2
3 => Fa3/1
5 => Gi0/0
4 => Gi0/1
-
[download]

I'd use something similar to one of the techniques found by searching for natural sort. Likely:

my @sortedIdx=
        map { unpack "N", substr($_,-4) }
        sort
        map {
            my $key = $oids{ifName}{$_};
            $key =~ s[(\d+)][ '0' . pack "N", $1 ]ge;
            $key . pack "CN", 0, $_
        } keys %{$oids{ifName}};
[download]

Though I'm a little curious why your integer indices are used to index a hash not an array. If your keys aren't just integers, then you'll need:

my @keys= ( keys %{$oids{ifName}} )[
        map { unpack "N", substr($_,-4) }
        sort
        map {
            my $key = $oids{ifName}{$_};
            $key =~ s[(\d+)][ '0' . pack "N", $1 ]ge;
            $key . pack "CN", 0, $_-1
        } 1 .. keys %{$oids{ifName}}
];
[download]

(Updated)

...searching for natural sort

Thanks! I had not heard that term before. That will be very useful.

Though I'm a little curious why your integer indices are used to index a hash not an array.

That's a really good question & embarassingly, I have no good technical answer. I suspect it is both because this is recycled code that I'm reworking to handle a larger data set, and the original keys were not integers; and because I work with hashes so much more than arrays that it's just a more comfortable method for me.

Thanks for pointing that out - I will re-think how I'm handling this data structure.

Update:After dinking around with this a bit: The integer index is an important key into other data structures (it's an ifIndex, if you are familiar with SNMP MIB-II). This was not obvious from my small example, sorry. The indices are not always sequential - often a few (or several, gah!) are missing here and there. For me, it's clearer (and therefore easier to maintain) to think of the integer as a hash key. Trying to work with an array for that was a very interesting exercise, thanks. :)