Whenever Perl tells you that two strings are not equal, odds are that Perl is propably right.

As you don't show any data, I can only guess: You have a list of names in @ops, and you read in another name, put it into the variable $who, and now try to check whether $who is a member of @ops. Then, it is likely that whitespace in one of the fields is tripping you.

Make sure you print your data before and after, and look out for whitespace:

foreach $member (@ops) {
    print "Comparing member '$member' against '$who'\n";
    if ($member eq $who) {
        $op = 1;
        last;
    };
};
[download]

Coincidentially, you might later on move to a more perlish construct:

$op = grep { $_ eq $who } @ops ? 1 : 0;
[download]

Which, by the way, is inefficient as it iterates through the whole @ops array even if the first element matches $who! A better approach is first in List::Util.

if (first { $_ eq $who } @ops) {
    print "matches";
}
[download]

You've left out a lot of the problem, but it looks like you might want a hash instead of an array. In your example, it looks like you simply want to check if an element is in the array.

Once you have the hash, you can use exists to check if the key is there. You won't have to go through a bunch of other elements and you won't have to care about comparing elements. :)

my %ops = map { $_, 1 } @ops; # create the hash however you like

my $op = exists $ops{$member} ? 1 : 0;
[download]

Alberto Simões talks more about this sort of thing in his article "Array Anti-Patterns" in the Fall 2005 issue of The Perl Review. :)

You left out a lot of detail, like the rest of the code. The comparison $member == $who is legitimate syntax, and if I make some assumptions about the surrounding code, it works fine here.

use strict;

my @ops = ( 1 .. 20 );
my $who = 10;
my $op;

foreach my $member (@ops) {
        if ($member == $who) {
                $op = 1;
                last;
        }
}
print "Found one\n" if $op;
[download]

Perhaps you could give us more detail to work with?

Scott

$ perl -e 'print "fred" eq "fred\n" ? "t" : "f","\n";'
f
$ perl -e 'print "fred" == "fred\n" ? "t" : "f","\n";'
t
[download]