This works for the sample supplied.

#! perl -slw
use strict;

while( <DATA> ) {
    $_ .= <DATA>;
    print join',', m[
        Username: \s+ (\S+) \s+ Owner: \s+ ([^\n]+ ) \n
        Last\sLogin: \s+ (\S+\s\S+) [^,]+, \s+ (\S+\s\S+)
    ]x;
}

__DATA__
Username: JANDERSON                            Owner:  JOE ANDERSON
Last Login: 14-JAN-2002 08:14 (interactive),  4-MAR-2002 17:09 (non-in
+teractive)
Username: PBARRETT                           Owner:  PAUL BARRETT
Last Login: 18-JAN-2006 08:14 (interactive),  24-MAR-2005 17:09 (non-i
+nteractive)
[download]

#!/usr/bin/perl -w
use strict;

my %users;
my $username;

while (<DATA>) {
    next if (/^\s*$/);
    chomp;
    if (/^Username\:\s+([A-Z]+)\s+Owner\:\s+(.*)$/) {
        $username = $1;
        $users{$username}{realname} = $2;
    }
    elsif (s/^(Last Login\:\s*)//) {
        ($users{$username}{i}, $users{$username}{ni}) = split /,/, $_;
    }
    else {
        die "line invalid - $_, $!\n";
    }
}

foreach my $user (keys %users) {
    print
        "$user,$users{$user}{realname},$users{$user}{i},$users{$user}{
+ni}\n";
}

__DATA__
Username: JANDERSON                            Owner:  JOE ANDERSON
Last Login: 14-JAN-2002 08:14 (interactive),  4-MAR-2002 17:09 (non-in
+teractive)
Username: PBARRETT                           Owner:  PAUL BARRETT
Last Login: 18-JAN-2006 08:14 (interactive),  24-MAR-2005 17:09 (non-i
+nteractive)
[download]

Comments:

• Your main problem is that you weren't correctly assigning to the hash. Instead of $login_times{ni} you need something like $login_times{$user}{ni]
• There is no need to quote your hash elements if they don't contain whitespace (it just makes the code more confusing)
• I re-named your hash as %users, so it makes more sense
• Your username pattern match was capturing all the whitespace following the username. If you can assume that all usernames will be uppercase letters only, then you could re-write that as /^Username\:\s+([A-Z]+)\s+Owner\:\s+(.*)$/

I should also note that the above code is quite fragile, insofar as it assigns the $username when it reads the first line, and then assumes that the username is the same when it gets to the second line. There are probably much better ways to go about this, which no doubt some other monks will point out :)

Cheers,
Darren :)

I think you're making the surrounding code too complicated:

while (<IN>) {
    next if /^\s*$/;
    chop;
 
    /^Username\:\s+ (.*?) \s+ Owner\:\s+ (.*?)\s*$/x and
       do { print "$1,$2,"; next };
 
    /^Last Login:\s+(\d+.*?\:\d+).*,\s*(\d+.*?\:\d+)/ and
       print "$1,$2\n";
}
[download]

Oh, actually, I forgot - the code also has to deal with lines like

Last Login:            (none) (interactive),            (none) (non-in
+teractive)
Last Login:            (none) (interactive), 12-SEP-1997 11:33 (non-in
+teractive)
Last Login: 11-JUL-2002 18:08 (interactive),            (none) (non-in
+teractive)
[download]

I figured I'd add to radiant.matrix's code like

    /^Last Login:\s+.*,\s*(\d+.*?\:\d+)/ and
       print "$1,$2\n";
[download]

but it's giving an error 'Unrecognized escape \d passed through..' I figure adding a condition to BrowserUK's regexp would work, too...

And what output would you want in those cases? The text '(none)' where the date should be?

#! perl -slw
use strict;

while( <DATA> ) {
    $_ .= <DATA>;
    print join',', m[
        Username: \s+ (\S+) \s+ Owner: \s+ ([^\n]+ ) \n
        Last\sLogin: \s+ ( .+ ) \s \( [^,]+, \s+ (.+) \s\(
    ]x;
}

__DATA__
Username: JANDERSON                            Owner:  JOE ANDERSON
Last Login: 14-JAN-2002 08:14 (interactive),  4-MAR-2002 17:09 (non-in
+teractive)
Username: PBARRETT                           Owner:  PAUL BARRETT
Last Login: 18-JAN-2006 08:14 (interactive),  24-MAR-2005 17:09 (non-i
+nteractive)
Username: LARRY                            Owner:  LARRY FINE
Last Login:            (none) (interactive),            (none) (non-in
+teractive)
Username: MOE                            Owner:  HARRY MOSES HOWARD
Last Login: 11-JUL-2002 18:08 (interactive),            (none) (non-in
+teractive)
Username: CURLY                            Owner:  JEROME HOWARD
Last Login:            (none) (interactive), 12-SEP-1997 11:33 (non-in
+teractive)
[download]

Gives

P:\test>junk
JANDERSON,JOE ANDERSON,14-JAN-2002 08:14,4-MAR-2002 17:09
PBARRETT,PAUL BARRETT,18-JAN-2006 08:14,24-MAR-2005 17:09
LARRY,LARRY FINE,(none),(none)
MOE,HARRY MOSES HOWARD,11-JUL-2002 18:08,(none)
CURLY,JEROME HOWARD,(none),12-SEP-1997 11:33
[download]

---

Examine what is said, not who speaks -- Silence betokens consent -- Love the truth but pardon error.

Lingua non convalesco, consenesco et abolesco. -- Rule 1 has a caveat! -- Who broke the cabal?

"Science is about questioning the status quo. Questioning authority".

In the absence of evidence, opinion is indistinguishable from prejudice.

#! perl

$/ = "Username: ";

my $re = q#^(\w+)\s+Owner:\s+(.+)\s+Last Login:\s*(.+?)\s*\(interactiv
+e\),\s*(.+?)\s*\(non-interactive\).*$#;

while (<>) {
    if (m|$re|ms) {
        printf "%s,%s,%s,%s\n",$1,$2,$3,$4;
    }
}
[download]