If you're on unix, you don't need the BEGIN{} block, and you'll need to use ^D instead ^Z. This assumes that any occurance of 'green red blue' are as shown in the examples, and not split across lines:

P:\test>perl -ln - text*
BEGIN{ @ARGV = map glob, @ARGV}
END{ print for sort keys %list }
s[green red blue][]g;
$list{ $ARGV }=1 if m[\b(green|red|blue)\b];
^Z
[download]

If the three words could be split across lines, and your files are not huge, then you could use this instead:

P:\test>perl -0777 -ln - text*
BEGIN{ @ARGV = map glob, @ARGV}
END{ $\="\n"; print for sort keys %list }
s[green\s+red\s+blue][]sg;
$list{ $ARGV }=1 if m[\b(green|red|blue)\b];
^Z
[download]

Often two regexen are better than one. Possible strategy: search for the strings you want and set a flag. Also check for the string you don't want and forget about that file immediately if you find it. (You may optimize it not to try to match the "good ones" if one has already been found.) Print the name of the file if the flag is set.

Update: minimal example with glob. If you want/need to use File::Find or one of its relatives, then adapt as needed. Hack && improve at will.

# untested
FILE: for (glob '*.txt') {
    open my $fh, '<', $_ or
      die "$_: D'Oh! $!\n";
    my $found;
    while (<$fh>) {
        /green|red|blue/ and $found++ if !$found;
        next FILE if /green red blue/;
    }
    print if $found;  # $\ eq "\n"
}
[download]

Or else if you trust in advance your files not to be huge, you may slurp in them all at once and simply

But do not cargo cult that into a (bad) habit, slurping is generally not recommended.

#!/usr/bin/perl

FILE: for my $file (glob '*.txt') {
    open my $fh, '<', $file or die "$file: D'Oh! $!\n";
    while (<$fh>) {
        /(?=^(?:(?!green red blue).)*$).*?(green|red|blue)/i;
    do { 
        print "$file \n";
        next FILE;
    } if $1;
     }
   }
[download]

(Any good reason why the shebang line is out of the code block?)

If you find that more readable... but if you knew, then why did you need to ask in the first place? In the meanwhile your regex has grown complex enough and I tired enough not to even try and understand it. ;-)

$headache++
$myTime--
$problem->{description}--
...

perl -e '$/=""; map {$c=0; $file=$_; open FH,$file; $_=<FH>; 1 while m
+/(?:green red blue)|(?:(green|red|blue)(?{$c++}))/g;  close FH; print
+ "$file matchs!\n" if $c } glob("*")'
[download]

$headache++ # take a asperine
$murciaTime++
$problem->{description}-- # how to do it better?
#...

#Thanks!
[download]

Hi Murcia,

If i understand your question correctly, Here is my code.

#get the files under a directory using readdir or glob.
my @a = qw(text1 text2 text3);# filenames in an array.
my @found;
foreach my $a (@a) {
   my $FH;
   open ($FH, $a) or die ("unable to open $a: $!\n");
   while (<$FH>) {
       if (m/green|blue|red/ && !m/green red blue/) {
           push @found ,$a;  
           last;
       }
    }
   close $FH;
}
print $_,$/ for (@found);
[download]

And if I understand his question correctly, this will fail if he has "this is green and yellow" on one line in a file and "green red blue" on the next one.