in reply to reading values from file

The loop in the middle is malformed (it appears to be missing a closing brace). In addition, you’re terminating the loop by closing the filehandle. That actually works as intended, but it’s kind of surprising. Further, you’re extracting a piece of information from the middle of a line by substituting the bits in front and after with nothing. Why not just match the bits you want?

The last three lines are kind of a non-sequitur. Where did $projectPath come from? Lastly, you never do anything with the values you calculate. What’s the point of the excercise? Is this a snippet that’s just part of a larger script? (Or maybe homework?)

Makeshifts last the longest.

Replies are listed 'Best First'.
Re^2: reading values from file
by perlNinny (Beadle) on Jan 24, 2006 at 20:53 UTC
    Nope, not homework. Yes, it is snippets of a larger script...these are just some examples of what I got to work but know there is a better way. Yes, I did forget the closing brace but, as I said, its just a snippet. However, I wonder why its bad to close the infile to exit the loop? It does two things, closes the file and exits the loop.
[reply]

      It works, but it’s surprising. I had to blink and stare for a moment before I noticed that it actually does do what you intended. All in all, considering the other things I mentioned, I’d write the loop like this:

      while ( <INFILE> ) {
    next if not /ver = '(.*?)'/;
    $old_version = $1;
    close INFILE;
    last;
}

      [download]

      Better yet, if you just opened the file:

      {
    open my $fh, '<', $filename
        or die "Can't open $filename: $!\n";

    while ( <$fh> ) {
        next if not /ver = '(.*?)'/;
        $old_version = $1;
        last;
    }
}

      [download]

      In which case $fh goes out of scope at the end of the block and the file is closed automatically; much nicer. I only explicitly close files that I write to (because they you want to check the return value of close, which may fail for such reasons as “disk full” or the like).

      In fact, if the file is so small that you don’t mind slurping it, you could just say

      use List::Util qw( first );

my $old_version = do {
    open my $fh, '<', $filename
        or die "Can't open $filename: $!\n";

    first { /ver = '(.*?)'/ } <$fh>;
};

      [download]

      Makeshifts last the longest.

[reply]
[d/l]
[select]

In Section Seekers of Perl Wisdom