This reeks of being a homework assignment, so my assistance will be limited to two items:

1: To generate a 2 digit random number, you could use something like:

$x = int(rand(100));
[download]

2: Read the Perl documentation. You could do something like this:

$y =~ s!^\d{2}!$x!;
[download]

The actual i/o and program logic will be left as an exercise.

This assumes that your sample data is a true reflection of it. Ie. Fixed length records of 12 chars + newline.

Update: Removed redundant regex.

#! perl -sw
use strict;

$/ = \39; ## Read 3 lines as a single record
while( <DATA> ) {
    my $rep = sprintf '%02d', int rand 100;
    substr $_,  0, 2, $rep;
    substr $_, 14, 2, $rep;
    substr $_, 27, 2, $rep;
    print;
}

__DATA__
57KXNWLRZWJ3
057E8bf0D030
057E8bf0D032
58KXNWLRZWKB
058E8bf0D02A
058E8bf0D02C
[download]

You're missing

substr $_, 23, 2, sprintf '%02d', rand 100;
substr $_, 36, 2, sprintf '%02d', rand 100;
[download]

and your int is useless.

I kinda assumed that once the OP had seen the idea of reading the data as fixed length records, he could probably work the rest out for himself.

As for the int being useless here, point taken. but it's a good habit I think to explicitly truncate the return from rand if you are trying to generate an integer result. In this case it will be autotruncated, but in other situations it will not.

---

Examine what is said, not who speaks -- Silence betokens consent -- Love the truth but pardon error.

Lingua non convalesco, consenesco et abolesco. -- Rule 1 has a caveat! -- Who broke the cabal?

"Science is about questioning the status quo. Questioning authority".

In the absence of evidence, opinion is indistinguishable from prejudice.

Like this?

my $num;

while (<FILE>) {
   chomp;

   if ($. % 3 == 1) {
      $num = sprintf("%02d", rand(100));
      substr($_, 0, 2, $num);
   } else {
      substr($_, 1, 2, $num);
      substr($_, -2, 2, sprintf("%02d", rand(100)));
   }

   print("$_\n");
}
[download]

If the line terminator is one character long, the above is simplifies to:

my $num;

while (<FILE>) {
   if ($. % 3 == 1) {
      $num = sprintf("%02d", rand(100));
      substr($_, 0, 2, $num);
   } else {
      substr($_, 1, 2, $num);
      substr($_, -3, 2, sprintf("%02d", rand(100)));
   }

   print;
}
[download]

Thanks everyone. I have another related question. Is it possible to randomly generate char within a certain range? For example if i want to generate two random chars between "aa" and "ff" so that the output will be like

ab 
ad
df
ca
.
.
.
[download]

PS. this is not a homework assignment. I finished college long ago. I just learn new tools to help me do my job and Perl is the mother of all tools.

ab 
ad
df
ca
.
.
.
[download]

Here are a couple of ways:

print join'',map{ chr 97+rand(6) } 1 .. 2 for 1 .. 100;

## Slightly wasteful, but you only do it once
## and reuse the array each time.

my @pairs = grep{ /[a-f]{2}/ }'aa' .. 'ff'; 
print $pairs[ rand @pairs ];
[download]

---

Examine what is said, not who speaks -- Silence betokens consent -- Love the truth but pardon error.

Lingua non convalesco, consenesco et abolesco. -- Rule 1 has a caveat! -- Who broke the cabal?

"Science is about questioning the status quo. Questioning authority".

In the absence of evidence, opinion is indistinguishable from prejudice.