Your function won't ever work if the pad character is a zero. Replace
$pad_char ||= ' ';
with
$pad_char = ' ' if not defined $pad_char;
to fix the problem.

Also, you could make your code a bit cleaner by replacing the last three lines with the following two:

my $pad = $pad_char x ($max_length - length $s);
return $dir eq 'R' ? "$s$pad" : "$pad$s";
[download]

Finally, you documented one of your assumptions ($s will never be longer than $max_length), but you didn't document your assumption that $pad_char will never be longer than one character.

In particular look for the section "Field filling".

---

DWIM is Perl's answer to Gödel

Perl6::Form does not seem to be a solution to a simpler form of this.

I would still need to create the template by using something like:

my $template = $dir eq 'R' ? '<' x $max_length : '>' x $max_length;
[download]

Also, I do not see anything about padding with a specific character. It seems Perl6::Form only pads with spaces.
See this portion now, thanks Grandfather.

Still quite a nice module though, I will have to remember it for general formatting in the future.

The idea would be to discard $max_length entirely. Whatever is providing the value stored in $max_length would now provide a form/template. Of course, this is not necessarily possible in your case.

I'd write that more concisely but essentially the same way. defined($pad_char) is preferred because the pad string might '0'.

sub my_pad {
  my ($s, $max_length, $dir, $pad_char) = @_;

  my $pad_string = (defined $pad_char ? $pad_char : ' ' ) x ($max_leng
+th - length $s);
  return $dir eq 'R' ? $s . $pad_string : $pad_string . $s;
}
[download]

In perl 5.10, it's shorter because of the new err operator. That's an import from perl 6.

Text::Autoformat?

Or Text::Format
Or not.

We're building the house of the future together.

use strict;
use warnings;


for (
["test", "l", 10, "*"],
["test", "r", 10, "*"],
["test", "l", 4, "*"],
["test", "r", 4, "*"],
["test", "l", 2, "*"],
["test", "r", 2, "*"],
["test", "l", 10],
["test", "r", 10],
["test", "l", 4],
["test", "r", 4],
["test", "l", 2],
["test", "r", 2],
)
{
    my $padded = pad (@{$_});
    print "=$padded=\n";
}

sub pad
{
    my $string     = shift || die "no string";
    my $direction  = shift || die "no direction";
    my $length     = shift || die "no lenght";
    my $char       = shift || " ";

    my $pad_length = $length - length($string);

    return $string if $pad_length <= 0;

    my $pad_string = $char x $pad_length;

    if ( $direction =~ /^l/i )
    {
        return $pad_string.$string;
    }
    elsif ( $direction =~ /^r/i )
    {
        return $string.$pad_string;
    }
    else
    {
        die "unknown direction";
    }
}
[download]

Just wanted to give you credit the pad sub. Works like it should. Easy to implement. Thanks.