my $first;
my $last;

{
   open(my $fh, '<', 'file')
      or die("Unable to open input file: $!\n");

   while (<$fh>) {
      $first = $_ if not defined $first;
      $last  = $_;
   }
}
[download]

or

use File::ReadBackwards ();

my $first;
my $last;

{
   open(my $fh, '<', 'file')
      or die("Unable to open input file: $!\n");

   $first = <$fh>;
}

{
   my $fh = File::ReadBackwards->new('file')
      or die("Unable to open input file: $!\n");

   $last = $fh->readline();
}
[download]

or

my $first;
my $last;

{
   open(my $fh, '<', 'file')
      or die("Unable to open input file: $!\n");

   ($first, $last) = (<$fh>)[0, -1];
}
[download]

1. Small files:

   perl -e "@l = <>; print 'first : ', $l[0], 'last  : ', $l[$#l];" filen
   +ame
   [download]

This approach is only recommended for small files because all the lines are being read to an array (copying everything to memory before printing the lines)


2. Medium sized files:

   perl -e "$first = <>; while($line = <>) { $last = $line; }; print 'fir
   +st : ', $first, 'last  : ', $last;" filename
   [download]

   This approach is recommended for medium sized files because it's reading one line at a time into memory.

   It's still not recommended for larges files because the entire file is being read. If you have a 4gbyte file and your I/O subsystem is only able to read 10 Mbytes/second you're going to take 400 seconds to get the answer.



3. Really large files
   For really large files you can read the first line normally (see above). To read the last line, you have to:

   • seek to the end of the file
   • search for the line terminator of the line before the last
   • read from the position of the character after the line terminator to the end of file.

   Update: Use File::ReadBackwards . I didn't knew about this module and ended up reinventing the wheel (and ended up with a square wheel when compared with File::ReadBackwards :-)


There's More Than Way To Do It,

• seek to the end of the file
• search for the line terminator of the line before the last
• read from the position of the character after the line terminator to the end of file.

Or use File::ReadBackwards as ikegami suggests.


holli, /regexed monk/

my $first  = `head -1 $filename`;
my $second = `tail -1 $filename`;
[download]

Why unportable? There are versions of "tail" and "head" for various OSses.


holli, /regexed monk/

Even if there are versions available for other OSses:
• not every tail and head accept the same set of arguments
• you may not have a compiler available to compile new tools
• you may not able to install new software on the machine you're working,
• Since you're using backticks, you're relying on whatever shell you have available, environment variables, aliases, (...)
The safest way is to rely only on the Perl interpreter.

Or, if you don't mind a little less portability in order to do one less sub-shell invocation:

my ( $first, $last ) = `head -1 $filename && tail -1 $filename`;
[download]

I guess the secret to it is in skipping the things in the middle.

1. Read lines
2. ...
3. Profit!

Or the George Costanza approach...

1. Open the file
2. yadda yadda yadda
3. First and last line.

                - Ant
                - Some of my best work - (1 2 3)

"You yadda'd the best part!"

"No, I told you about opening the file."

*Cue scene change bass riff*