Re: Splitting a string

Finally, one line, and no experimental features!

sub double_it {
   return join ' ', $_[0] =~ /\w(?=\w(?<=(..)))/g;
}
[download]

Alternate versions:

sub double_it {
   local ($_) = @_;

   (my @chars1) = (my @chars2) = split //;
   pop   @chars1;
   shift @chars2;

   return join ' ',
          grep { !/\s/ }
          map { $chars1[$_] . $chars2[$_] }
          0..$#chars1;
}
[download]

sub double_it {
   local ($_) = @_;

   my @list = /(\w)(?=(\w))/g;

   my @pairs;
   push(@pairs, shift(@list).shift(@list))
      while @list;

   return join(' ', @pairs);
}
[download]

sub double_it {
   our @pairs; local *pairs;
   () = $_[0] =~ /(\w)(?=(\w))(?{ push(@pairs, "$1$2"); })/g;
   return join(' ', @pairs);
}
[download]

Comment on Re: Splitting a string Select or Download Code

Replies are listed 'Best First'.
Re^2: Splitting a string by nobull (Friar) on Feb 08, 2006 at 18:32 UTC
`/\w(?=\w(?<=(..)))/g;` [download] Isn't that rather more complicated than necessary? `/(?=(\w\w))./g;` [download]	[reply] [d/l] [select]
Re^3: Splitting a string by japhy (Canon) on Feb 08, 2006 at 19:19 UTC
The `.` is unnecessary. Jeff `japhy` Pinyan, P.L., P.M., P.O.D, X.S.: Perl, regex, and `perl` hacker How can we ever be the sold short or the cheated, we who for every service have long ago been overpaid? ~~ Meister Eckhart	[reply] [d/l]
Re^4: Splitting a string by nobull (Friar) on Feb 25, 2006 at 15:37 UTC
It is true that `/PATTERN/g` will DWIM when `/PATTERN/` matches the empty string and not find an infinite number of matches as the same point. I, however, consider code that relies on this behaviour in order save one character to be less simple.	[reply] [d/l] [select]