rudeb0y has asked for the wisdom of the Perl Monks concerning the following question:

Just a general question....no code. Is there a way to wrap a timer around a system call.? I have a command that will timeout after 5 minutes. Is there a way to make the subroutine go to the next element for processing...say after 2 minutes.?? Any help/leads would be helpful.

Replies are listed 'Best First'.
Re: Timer Question
by ikegami (Patriarch) on Feb 16, 2006 at 19:28 UTC
    fork a child, then monitor (alarm+waitpid) the child in the parent. I'm no expert at working with child processes, but I came up with the following. Once the child has run for $timeout seconds, the parent asks the child to terminate. If the child is still running 10 seconds later, the parent forcefully kills the child. 
    my @command = "sleep 10; echo awoke";
my $timeout = 5;

my $cpid = fork();

die("Unable to fork: $!\n")
   if not defined $cpid;

if (not $cpid) { # In child
   exec(@command);
   die("Unable to exec: $!\n");
}

eval {
   local $SIG{ALRM} = sub { die "alarm\n" };
   alarm($timeout);
   waitpid($cpid, 0);
};
alarm(0);

if ($@) {
   die $@ if $@ ne "alarm\n";

   warn("Long running child. Attempting to terminate.\n");
   kill 'TERM', $cpid;

   eval {
      local $SIG{ALRM} = sub { die "alarm\n" };
      alarm(10);
      waitpid($cpid, 0);
   };
   alarm(0);

   if ($@) {
      die $@ if $@ ne "alarm\n";

      warn("Long running child. Attempting to kill.\n");
      kill 'KILL', $cpid;

      eval {
         local $SIG{ALRM} = sub { die "alarm\n" };
         alarm(5);
         waitpid($cpid, 0);
      };
      alarm(0);

      if ($@) {
         die $@ if $@ ne "alarm\n";

         warn("Unable to kill long running child.\n");
      } else {
         warn("Long running child successfully killed.\n");
      }
   } else {
      warn("Long running child successfully terminated.\n");
   }
}

    [download]
    Output: 
    $ perl script.pl
Long running child. Attempting to terminate.
Long running child successfully terminated.

    [download]
[reply]
[d/l]
[select]
Re: Timer Question
by saintmike (Vicar) on Feb 16, 2006 at 18:47 UTC
[reply]
[d/l]

      That's didn't work prefectly. 

      $ perl -e 'alarm(5); system("sleep 10; echo awoke")'
Alarm clock
$ awoke

      [download]

      system was interupted, but the command kept executing.

[reply]
[d/l]
        Depends on what is meant by "system call".

        If it's system call, it's a call to the OS, like sysread, in which case alarm works exactly as required.

        If it's "system() call", then things are different: system() forks a process, executes whatever's specified (different for single/multiple arguments), waits until the command is completed and then returns. It won't kill the spawned process, that's why it will run until the end.

[reply]
[d/l]
[select]

Back to Seekers of Perl Wisdom