Regexps are useful for validation, extraction and tokenizing. However, they are not as strong at parsing, as you have discovered. Parsing is nontheless possible, using advanced features.

use v5.8.0;  # or higher  # For $^N

our @rv;
our @temp_rv;

/
   (text);
   (?{ local @temp_rv = ( @temp_rv, $^N ) })

   (?:
      (float)
      (?{ local @temp_rv = ( @temp_rv, $^N ) })
      (?:non-num)
   ){4}

   (?{ @rv = @temp_rv })
/x;
[download]

Tested.

• local is needed in case of backtracking.
• @rv = @temp_rv is necessary because @temp_rv will wind back to its original value before the regexp exits.
• Package (our) variables (rather than lexical (my) variables) are needed because the code blocks in the regexp act as closures.

Don't eschew $^R! That's what it's there for:

# UPDATED: added comments about what's going on
our @rv;  # you like taking trips? ;)

m{
  (text);

  # the (?{ ... }) block's return value
  # is given to $^R, the magical variable
  # whose value is auto-localized and gets
  # rolled back when backtracking occurs.
  # $^R's initial value, then, is an array
  # ref with one element, $1's value.
  (?{ [$1] })

  (?:
    (float)

    # then, four times, we add the float we
    # match in $2 to the end of $^R.  we
    # can't just do push(@{$^R}, $2), because
    # that would break the auto-rollback magic,
    # so instead, we just let the return value
    # set $^R again.
    (?{ [ @{$^R}, $2 ] })
    non-num
  ){4}

  # finally, we store @{$^R} in @rv.
  (?{ @rv = @{$^R} })
}x;
[download]

---

Jeff japhy Pinyan, P.L., P.M., P.O.D, X.S.: Perl, regex, and perl hacker
How can we ever be the sold short or the cheated, we who for every service have long ago been overpaid? ~~ Meister Eckhart

So you'll probably want to do this in two steps. I'll pretend you have a $float regex and a $non_num regex:

($text, $nums) = /(text);((?:$float$non_num){4})/;
@nums = split $non_num, $nums;
[download]

You have only two sets of capture brackets so you only get two captures. Your suggestion of duplicating the counted match is probably the best answer in this case - that's what copy and paste is for in your editor :)

#!/usr/bin/perl

use strict;
use warnings;

use Data::Dumper::Simple;

# (text);(?:(float)[non-num]){4};
my $text = "asdf;12.34x23.45y34.56z45.67n";
my @matches = ($text =~ /([\d.]+\D)/g);
print Dumper(@matches);
[download]

In addition to the other solutions posted, you can break up the regex using /g and \G and do the looping yourself.

my @submatch;

{
    $str =~ /(text);/g or last;
    push @submatch, $1;

    for( 1 .. 4 ) {
        $str =~ /\G(?:(float)[non-num])/g or do {
            @submatch = ();
            last;
        }
        push @submatch, $1;
    }
}
[download]

Makeshifts last the longest.