my $l = do{ use bytes; length $my_string };
print $l;
[download]

$i=256;
while (1)
{
    print ++$i, "\n";
    system ("perl -e \"\$_ = 'x' x ($i*1024*1024)\"");
}
[download]

why shell out?

my $i=1;
my $x;
while (1)
{
    print $i, "\n";
    $x = 'x' x ($i*1024*1024);
    $i += 10;
}
[download]

happily eats up all my memory

Thank You everyone for your replies....:-) In the meantime I've found out where the problem was, but i will post the code, and an example of input data, nevertheless. Please note that the purpose of this code is to test an algorithm, and it's not a final version of the program i have in mind.

system "clear";
print "Palindrome - gamma version\n";
print "--------------------------\n\n";
print "Please enter DNA filename: ";
$filename=<STDIN>;
chomp $filename;
    unless (-e $filename) {
        print "No such file...exiting\n\n";
        exit;
    }
    unless (open(DNASEQ, $filename)) {
        print "Cannot open file...exiting\n\n";
        exit;
    }    
@dna=<DNASEQ>;
$dna=join('', @dna);
$dna=~ s/\s//g;
$count_of_2=0;
    for ($lb=0; $lb<length $dna; ++$lb) {
            $lba=substr ($dna, $lb, 1);
            $rba=substr ($dna, $lb+1, 1);
            $rba=~ tr/atgc/tacg/;
                if ($lba eq $rba) {
                    ++$count_of_2;
                }
                else {
                }
    }
print "Number of 2bp palindromes: ", $count_of_2, "\n";
exit;
[download]

Input data are files that contain DNA sequences arranged in the following format:


CGACAGCTACGATCGTAC
CAGTATCATCACTACGTA
CACGAGAGTACGATCGAC
......etc.........
[download]


The program should work with both lower- and uppercase sequences, but i forgot to add something like

$dna=~ tr/ATGC/atgc/;
[download]


so when i loaded uppercase DNA sequence it just didn' do the job right. Now the two programs give the same results, i've tested them with sequences containing up to 29160000 characters.

Out of curiosity: How long is the C sourcecode your friend wrote? And ... Have you ever looked at bioperl?


holli, /regexed monk/

hi Berislav,
i think, you have 2 problems on your code:

1. for ($lb=0; $lb<length $dna; ++$lb), the lenght of the array must be length($dna) -1 (the last elemet cannot be compared with anything ... perl accepts this, though)
2. the 'tr' only tries to convert between lowercase letters. The example you gave us have uppercase letters ... the result isn't the same ...

#!/usr/bin/perl -w
use strict;

system "clear";
print "Palindrome - gamma version\n";
print "--------------------------\n\n";
print "Please enter DNA filename: ";

my $filename=<STDIN>;
chomp $filename;
die "No such file...exiting\n\n" unless (-e $filename);
open(DNASEQ, $filename) or die "Cannot open file...exiting\n\n";

my $last_protein;
my $count_of_2=0;
while (<DNASEQ>) {
        chomp;
        my ($lba,$rba)= ($last_protein, undef);
        for (my $lb = 0; $lb < (length) - 1; ++$lb) {
                $lba  =  substr ($_, $lb, 1);
                $rba  =  substr ($_, $lb+1, 1);
                $rba  =~ tr/atgcATGC/tacgTACG/;
                ++$count_of_2 if ($lba eq $rba);
        }
        $last_protein = $rba;
}
print "Number of 2bp palindromes: ", $count_of_2, "\n";
[download]

hope that helps :-)

use warnings;
use strict;

system 'clear';
print "Palindrome - gamma version\n";
print "--------------------------\n\n";
print 'Please enter DNA filename: ';
chomp( my $filename = <STDIN> );

open DNASEQ, $filename or die "Cannot open $filename: $!";

( my $dna = do { local $/; <DNASEQ> } ) =~ tr/atcgATCG//cd;

my $count_of_2 = () = $dna =~ /a(?=t)|t(?=a)|c(?=g)|g(?=c)/ig;

print "Number of 2bp palindromes: ", $count_of_2, "\n";

__END__
[download]