Since you know that the header is the top 11 lines (lines 0 .. 10), then you could do something like this (a simple script to display the desired lines, which just loops thru the lines starting with the 12th line):

#!/usr/bin/perl -w

use strict;
use LWP::Simple;

my $stats_url = q{http://vspx27.stanford.edu/teamstats/team32.txt};

my $stats_txt = get($stats_url);
my @lines = split(/\n/, $stats_txt);

foreach my $i (11 .. $#lines) {
    print $lines[$i], qq{\n};
    my @line_parts = split(/\s+/, $lines[$i]);
    # do something with the parts here, if desired....
}
[download]

Another way, if you're looping thru a text file, is to look at the value of $., which contains the current line number of the last file handle accessed, and just use something like next if ($. < 11); in your loop as you read thru the file. Example:

#!/usr/bin/perl -w

use strict;

my $data_file = qq{team32.txt};

open(DF, $data_file) 
  or die(qq{Can't open $data_file for input: $!\n});
while (<DF>) {
    next if ($. < 11);
    chomp;
    print $_, qq{\n};
    my @line_parts = split(/\s+/);
    # do something with the parts here, if desired....
}
close(DF);
[download]

Hope that helps.

#!/usr/bin/perl -w

use strict;

my $sect=0;  # Not in a section yet
while (<>) {
  if ($sect==1) {
    if (/(\d+)\s+(.+)\s+(\d+)\s+(\d+)\s*$/) {
      # Correct section AND format, assumed valid
      print "Sec1: $1, $2, $3, $4\n";
    }
    else {
      $sect=0; # Wrong fmt, end of sect assumed
    }
  }
  elsif ($sect==2) {
    if (/(\d+)\s+(\d+)\s+(.*)\s+(\d+)\s+(\d+)\s+(\d+)\s*/) {
      print "Sec2: $1, $2, $3, $4, $5, $6\n";
    }
    else {
      $sect=0;
    }
  }
  elsif (/^team\s+teamname\s+score\s+wu$/) {
    # Start of team info section
    $sect=1;
  }
  elsif (/^rank\s+team rank\s+name\s+credit\s+total\s+team$/) {
    # Start of rank info section
    $sect=2;
  }
  else {
    # Uninteresting line, ignore it...
  }
}
[download]