Without really checking your code in detail, it looks like you want this:

my($a,$c,$g,$t) = (0, 0, 0, 0);
# or
my($a,$c,$g,$t) = (0) x 4;
[download]

Your version:

That initializes $a to "0" and doesn't assign any value to the other variables.

The error occur because you're are only initializting $a. Try:

my ($a,$c,$g,$t) = (0, 0, 0, 0);
[download]

or

my $a = 0;
my $c = 0;
my $g = 0;
my $t = 0;
[download]

Notice the lack of quotes around a numerical zero.

Aside from that,

• you have lots of redundancy,
• you use the less readable form of for,
• you use $a which is special, and
• you use four seperate vars ($a,$c,$g,$t) where a hash would be better.

Fix:

sub comNucCount {
    my($string1, $string2) = @_;
    $string1 = uc $string1;
    $string2 = uc $string2;

    my %counts = map { $_ => 0 } qw( A C G T );

    for my $position (0 .. length($string1)-1) {
        my $char = substr($string1,$position,1);
        $counts{$char}++
            if substr($string2, $position, 1) eq $char;
    }

    return "A=$counts{A}, C=$counts{C}, G=$counts{G}, T=$counts{T}";
}
[download]

Another way to do it - avoid all that fiddly substr stuff:

use strict;
use warnings;

print comNucCount('acgtacgtacgtacgt', 'aaaaccccggggtttt'), "\n";

sub comNucCount {
    my @str1 = split '', lc shift;
    my @str2 = split '', lc shift;
    my %counts = (a => 0, c => 0, g => 0, t => 0);
    
    for (@str1) {
        last if ! @str2; # Length mismatch - done
        $counts{$_}++ if $_ eq shift @str2;
    }

    return "A=$counts{'a'}, C=$counts{'c'}, G=$counts{'g'}, T=$counts{
+'t'}";
  }
[download]

Prints:

A=1, C=1, G=1, T=1
[download]