First, for $i ([A-Z]) { ... } doesn't do what you think it does. This is not a regex; [A-Z] doesn't mean "A" through "Z". For that, you want for $i ('A' .. 'Z') { ... }.

Second, s/$i/($j+6)/i doesn't execute the right-hand side as code unless you add the /e modifier: s/$i/$j+6/ie. And you'll want to add the /g modifier as well, to replace all occurrences of A with 6, B with 7, etc.

Finally, your second substitution is broken. It will replace 6 with A, but it will also change 16 into 1A. You'll need \b (word boundary) in the regex to restrict the matching: s/\b$g\b/$i/g;. And the /i modifier is useless in this case.

How about using tr/// ?

$string =~ tr/n-za-m/a-z/;
[download]

Cheers, Flo

How does tr/// work, exactly? I can't find it in the perlops.
Thanks.

See

tr/SEARCHLIST/REPLACEMENTLIST/cds
y/SEARCHLIST/REPLACEMENTLIST/cds

in perlop. It's around line 1100 in my version.

Transliteration is what you're trying to do- map one set of characters onto another set. Specifically, you're trying to implement rot6, a transliteration cipher (not much of an encryption, btw).

tr///, aka y///, uses the second set of characters to replace their counterparts from the first set.


my $word = "abc";
$abc =~ tr/acb/llo/;
print $word;
[download]

yeilds: lol

Use this link: tr///

-QM
--
Quantum Mechanics: The dreams stuff is made of

Fixed up, your code would be

use strict;
use warnings;

my $rot = 6;

chomp(my $message = lc(<>));
$message =~ s/([a-z])/
   chr( ( ord($1) - ord('a') + $rot + 26 ) % 26 + ord('a') )
/ge;
print("$message\n");
[download]

use strict;
use warnings;

my $rot = 6;

my $src = join '', 'a'..'z';
my $dst = substr($src, $rot) . substr($src, 0, $rot);

chomp(my $message = lc(<>));
eval "\$message =~ tr/$src/$dst/;";
print("$message\n");
[download]

use strict;
use warnings;

my $rot = 6;

my $src = join '', 'a'..'z';
my $dst = substr($src, $rot) . substr($src, 0, $rot);

my $tr = eval "sub {
   local \$_ = \@_ ? \$_[0] : \$_;
   tr/$src/$dst/;
   return \$_;
}";

chomp(my $message = lc(<>));
$message = $tr->($message);
print("$message\n");
[download]

Set $rot to -6 to "decrypt".

This method of encrpytion is particularly bad because

• the frequency of the letters remains unchanged making the cypher easy to identify and the cyphertext easy to decrypt by observing the statistical distribution of the letters, and
• the punctuation remains unencrypted, making the cyphertext easy to decrypt by observing the statistical length and organization of the words.