Extract the field, then convert to hex if needed:

my %hex = map { $_ => 1 } qw( AB CD B1 );

my @records = (
   pack("A2Ca7",  "RT", 7, "testing"),
   pack("A2CH16", "CD", 8, "01020304FFDDEC19"),
);

foreach my $record (@records) {
   my ($kw, $rdata) = unpack("A2C/a", $record);

   $rdata = uc(unpack('H*', $rdata))
      if $hex{$kw};

   print "$kw $rdata\n";
}
[download]

or use a dispatch table to avoid the if:

sub format_as_text { return $_[0];                   }
sub format_as_hex  { return uc(unpack('H*', $_[0])); }

my %kwfmt = (
   RT => \&format_as_text,
   PN => \&format_as_text,
   SN => \&format_as_text,
   AB => \&format_as_hex,
   CD => \&format_as_hex,
   B1 => \&format_as_hex,
);

my @records = (
   pack("A2Ca7",  "RT", 7, "testing"),
   pack("A2CH16", "CD", 8, "01020304FFDDEC19"),
);

foreach (@records) {
   my ($kw, $rdata) = unpack("A2C/a", $_);
   $rdata = $kwfmt{$kw}->($rdata);
   print "$kw $rdata\n";
}
[download]

By the way, there's no reason to hardcode the number of elements in the array. Instead of
for (my $i=0; $i<2; $i++)
you should use
for (my $i=0; $i<@records; $i++)
Or better yet, use
for my $i (0..$#records)
since it's easier to read and just as efficient. I used
foreach my $record (@records)
since it's even simpler and we didn't care about the record index.