The third occurence of a string can be found by stepping through your substring with index. Since ',' is a simple string, not a pattern, index is ideal.

On the other hand, if you really do want to search for a particular pattern, here's one way to do it with respect to finding the third comma, using a regexp:

use strict;
use warnings;

my $string = "a,bc,d,efg";

if( $string =~ m/(?:,[^,]*){2}(,)/ ) {
    print $';
}
[download]

# $n is the nth wanted occurence, as indicated by the question.
# $i holds how many times we found the pattern

my $str     = ',n ,pple , d,y';
my ($n, $i) = 4;


$str =~ / ,                  # we are searching for the , pattern 
          (?{ $i++})         # we found it again , increament $i 
        /xgc                 # retain last occurance on failure
        for (1..$n);

# print position in string
print +($n == $i)   ?  pos($str) - 1
                    : 'not found';
[download]

$str = "The, Sample, sents, kdsjf, jdfhj";
for (split(/,/, $str,3))
{
print ;
}
[download]

$cnt =0;
while($str =~ /(.*?),/g)
{
$cnt++;
print $&, if($cnt ==3);
}
[download]

keep a counter to count the number of occurrences of the pattern,
initially -1 (assuming 0-based indexing)

keep a marker to note the position of the pattern

run loop from the start of a line to its end

  check if pattern exists
    if not,
      exit out of loop

    else
       check if counter is same the nth-place required
       if yes,
          exit out of loop

       else,
         increment the counter
         set the marker to the start of the pattern
         loop the loop from the marker + the length of the pattern + 1

at the end, equivalence of counter & desired nth occurrence will
give you the result.
[download]

Replacing nth occurrence of string will be helpul for you.

Welcome to monks group

Employing a little regex look ahead trickery gives something like this:

use strict;
use warnings;

my $pat = 'ono';
my $str = <<STR;
ono is the pattern to match. ono is found once in onono
STR
#123456789012345678901234567890123456789012345678901234
#         1         2         3         4         5    

for my $count (1..4) {
    if ($str =~ /(?:(?:(?!$pat).)*($pat)){$count}/) {
        print "Match at $-[1] for count = $count\n";
    } else {
        print "No match for count = $count\n";
    }
}
[download]

Prints:

Match at 0 for count = 1
Match at 29 for count = 2
Match at 50 for count = 3
No match for count = 4
[download]

Note that at least simple regex matches are fine in the pattern including look ahead and look back matches, but avoid capture groups.

In perl6 it's m:3rd/,/ and .pos will tell you at what position it matched. :-)

use strict;
use warnings;

my ($str, $nth, $find, $p);

$str = "dsf,sdg,hjhgj,gjkh";
$nth = 3; $find = ',';

$str =~ m/(?:.*?$find){$nth}/g;
$p = pos($str) - length($find);
print substr($str, $p) if $p > -1;
[download]

use strict;
use warnings;

my ($str, $nth, $p);

$str = "dsf,sdg,hjhgj,gjkh";
$p = -1; $nth = 3;

while ($str =~ /,/g) {
    $p = pos($str) - length($&), last if !--$nth;
}
print substr($str, $p) if $p != -1;
[download]

pos($str) - length($&)? Ewwww. First of all, $& is a Curse, and second, you can just use $-[0] to get the same location.

while ($str =~ /,/g) { $p = $-[0], last if !--$nth }
[download]

---

Jeff japhy Pinyan, P.L., P.M., P.O.D, X.S.: Perl, regex, and perl hacker
How can we ever be the sold short or the cheated, we who for every service have long ago been overpaid? ~~ Meister Eckhart