You need the string equality op, 'eq', not assignment, '='. You can keep track of how many matches you have by incrementing a variable in the true branch. As it's written, the else branch is unnecessary; control goes to the next iteration anyway.

my $counter;

for (@array) {
    if ($hash{$_} eq "correct_value") {
        $counter++
        print "$_ Success\n";
        last;
    }
}

print 'We have a match.', $/ if $counter;
[download]

Update: Albannach++ quickly spotted an error, repaired.

This surely popped somewhere else here in PM (I kinda remember something), but I did a supersearch for $/ without finding anything applicable. Why:

print 'We have a match.', $/
[download]

instead of

print "We have a match.\n"
[download]

(apart from TIMTOWTDI)? Pointers welcome!

Flavio
perl -ple'$_=reverse' <<<ti.xittelop@oivalf

Don't fool yourself.

Force of habit, mainly. I usually prefer giving print a list to concatenating strings and variables first. The habit just carries over to control characters like this, too.

I used to believe that $/ had some advantage over "\n" in platform independence, but I'm over that now.

After Compline,
Zaxo

A good answer needs a little more context. For example, if the loop is in a sub then you can return rather than last when you get and have dealt with the match:

# always use strictures (the following two lines)
use strict; 
use warnings;

my @array = qw(key1 key2 key3 key4);
my %hash = (key2 => undef, key4 => 'The goods', key5 => 'More goods');

doLoop ();

sub doLoop {
    for my $key (@array) {
        next if ! exists $hash{$key}; # Skip if the key is not used in
+ the hash
        next if ! defined $hash{$key}; # Skip if the key exists, but i
+s undefined
        next if $hash{$key} ne 'No goods';
        print "The value for '$key' is '$hash{$key}'\n";
        return;
    }
    
    print "Failed to find matching key\n"
}
[download]

Prints:

Failed to find matching key
[download]

Without the sub, or if there is more work to do following the loop, you need to keep note of match success. Something like:

use strict; 
use warnings;

my @array = qw(key1 key2 key3 key4);
my %hash = (key2 => undef, key4 => 'The goods', key5 => 'More goods');
my $match = 0;

for my $key (@array) {
    next if ! exists $hash{$key}; # Skip if the key is not used in the
+ hash
    next if ! defined $hash{$key}; # Skip if the key exists, but is un
+defined
    next if $hash{$key} ne 'No goods';
    
    print "The value for '$key' is '$hash{$key}'\n";
    $match = 1;
    last;
}

print "Failed to find matching key\n" if ! $match;
[download]

In the past, I've encountered warnings from perl about exiting a loop via return and expected your first example to generate one. However, when I tested it (even after modifying key2's undef to "No goods" to get a successful match), the example code produced no such warning. So now I'm confused...

Any idea why this example code doesn't emit a warning about exiting the loop via return? (Unfortunately, I've long since fixed my code to remove that warning and don't recall the details clearly enough to provide an example which produces it.)

If you try to return when not in a sub you get:

use strict;
use warnings;

return 10;
[download]

Prints:

Can't return outside a subroutine at noname2.pl line 4.
[download]

---

DWIM is Perl's answer to Gödel

FIND_MATCH:
{
  foreach my $a (@array)
  {
    if( $hash{$a} eq 'correct_value' )
    {
      print 'Success';
      last FIND_MATCH;
    }
  }
  warn "Didn't find a suitable match!";
}
[download]

@matches = grep {$hash{$_} eq "correct_value"} @array;

if (@matches){
   print "Success"
} else {
   warn "no match"
}
[download]

that next is useless, as long as you don't last, the loop is going to continue until it reaches the last element of the array.

if ($hash{$a} = "correct_value")
{  print "Success"; $flag = 1; last; }
[download]

if ($condition) 
     {foo(); bar();}
[download]

if ( $condition ) {
    foo();
    #easily read and/or insert & modify code here
    bar();
}
[download]

print +(first { $_ eq 'correct_value' } @arr) || 'not found';

Alternatively, if you can get your hands on it, List::MoreUtils has a bunch of small, but useful subroutines.
-----------------------------


use List::MoreUtils qw(any);

...

print "Success" if any { $_ eq "correct_value" } @hash{@array};
[download]

-----------------------------
Notes:
1 - note the use of a hash slice; it takes some getting used to, having a @ instead of a % in front.
2 - please use something more meaningful than %hash or @array as var names in your actual code :)