open my($fh), "<", "/path/to/file" or die "can't read /path/to/file: $
+!";
while (my $line = <$fh>) {
  # do stuff with $line
}
close $fh;
[download]

Personally, I'd read everything into a hash.

use Data::Dumper;

my (%quiz, $number);
while (<DATA>){
    chomp;
    if (s/^(\d+)\. *//) {
        $number = $1;
        $quiz{$number}{question} = $_;
    }
    elsif (s/^([A-Z])\. *//) {
        my $option = $1;
        $quiz{$number}{answer} = $option if s/ *\*$//;
        $quiz{$number}{$option} = $_;
    }
    else {
        next;
    }
}

print Dumper \%quiz;

__DATA__
1. What is my name?
A. Rooney *
B. Gerrard
C. Ronaldo
D. Ronaldinho
2. Who's your bet in the coming World Cup?
A. Brazil *
B. Germany
C. England
D. Cameroon
[download]

You can then do things like: "What is the answer to question two?"

print $quiz{2}{$quiz{2}{answer}};
[download]

or, "Display question 1:"

print '1. ',$quiz{1}{question},"\n";
for ( sort keys %{$quiz{1}} ){
    print "$_. ",$quiz{1}{$_},"\n" if $_ !~ /\p{Lower}/;
}
[download]

or, "Display them all:"

for (sort keys %quiz) {
    my $number = $_;
    print "\n$number. $quiz{$number}{question}\n\n";
    for ( sort keys %{$quiz{$number}} ){
        next if /question|answer/;
        print "$_. $quiz{$number}{$_}\n";
    }
    print "\nAnswer: $quiz{$number}{answer}\n";
}
[download]

Update: or a little clearer:

for (sort keys %quiz) {
    my $current = $quiz{$_};
    print "\n$_. $current->{question}\n\n";
    for ( sort keys %{$current} ){
        next if /question|answer/;
        print "$_. $current->{$_}\n";
    }
    print "\nAnswer: $current->{answer}. $current->{$current->{answer}
+}\n";
}
[download]

i dont know if this example could help you any

# File containing Q&A
my $file = 'Q.txt';

open(FH,$file) or die $!;
while (my $line = <FH>) {
    if ($line =~m/^\d+\./) {
        print "Question : $line";
    }else{
        print $line;
    }
}
close(FH);
[download]

Update : if you want to remove "*" from the end just add the following line after the while loop

$line =~s/\*$//;
[download]

#!/usr/bin/perl

use strict;
use warnings;

use Data::Dumper;

my %questions;
my $cur;

while (<DATA>) {
    $cur = $1 if /^\d+\.\s*(.*)$/;
    $questions{$cur}->{selected} = $1 if $cur and /^[A-Z]+\.\s*(.*)\s+
+\*$/;
    s/\s*\*\s*$//;
    push @{$questions{$cur}->{answers}}, $1 if $cur and /^[A-Z]+\.\s*(
+.*)\s*$/;
}

print Dumper \%questions;

__DATA__
1. What is my name?
A. Rooney *
B. Gerrard
C. Ronaldo
D. Ronaldinho
2. Who's your bet in the coming World Cup?
A. Brazil *
B. Germany
C. England
D. Cameroon
[download]

Building your question sheet in a hash seems to be the way to go. The following code reads the quiz into a hash then reprints the form slightly reformatted.

use strict;
use warnings;

my %questions;
my $question = 0;

while (<DATA>) {
    chomp;
    my ($prefix, $text, $tag) = /^(\w+)\.\s*((?:(?!\*$).)*)(\*)?$/;
        next if ! defined $text;

    if ($prefix =~ /^\d+/) {
        $question = $prefix;
        $questions{$question}{Question} = $text;
    } else {
        push @{$questions{$question}{Answers}}, "$prefix. $text";
        $questions{$question}{Answer} = "$prefix. $text" if defined $t
+ag;
    }
}

# Print the question sheet
for my $num (sort keys %questions) {
    print "$num. $questions{$num}{Question}\n";
    
    for (@{$questions{$num}{Answers}}) {
        print "   $_";
        print " (answer)" if $_ eq $questions{$num}{Answer};
        print "\n";
    }
}

__DATA__
1. What is my name?
A. Rooney *
B. Gerrard
C. Ronaldo
D. Ronaldinho
2. Who's your bet in the coming World Cup?
A. Brazil *
B. Germany
C. England
D. Cameroon
[download]

Prints:

1. What is my name?
   A. Rooney  (answer)
   B. Gerrard
   C. Ronaldo
   D. Ronaldinho
2. Who's your bet in the coming World Cup?
   A. Brazil  (answer)
   B. Germany
   C. England
   D. Cameroon
[download]