Re: mkfifo/mknode

You should use the warnings and strict pragmas so the second and third lines of your program should be:

use warnings;
use strict;
[download]


chomp($pid  = $$);
[download]

$$ does not contain a newline so there is no point in using chomp().


$LOCK_EXCLUSIVE = 2;
$UNLOCK         = 8;
[download]

You should use the constants from the Fcntl module:

use Fcntl ':flock';
[download]


$fifo             = "ENV{HOME}/a_file";
[download]

You probably meant to use the %ENV hash there:

$fifo             = "$ENV{HOME}/a_file";
[download]


close(FILE) || warn "update queue file exited $?\n";
[download]

The $? variable will only contain useful information if you are running an external program. which you are not. However, you should include the $! variable in any system error messages.


close(LOCK) || warn "lock file exited $?\n";;
$str=`cat $fifo.lock`;

flock LOCK, $UNLOCK;
[download]

close(LOCK) will also unlock the file so the subsequent attempt to unlock it is superfluous.


system("rm $fifo.lock");
[download]

Is there a reason that you couldn't use the built-in unlink function?

Have you read the entries in perlfaq5 on file locking?

You are locking the PID file but not the data file. This may work better:

#!/usr/local/bin/perl
use warnings;
use strict;

use Fcntl ':flock';
use Tie::File;

my $fifo = "$ENV{HOME}/a_file";
my $lock = "$fifo.lock";

tie( my @pid, 'Tie::File', $lock )->flock( LOCK_EX )
    or die "Cannot open '$lock' $!";

@pid = $$;

tie( my @lines, 'Tie::File', $fifo )->flock( LOCK_EX )
    or die "Cannot open '$fifo' $!";

( my $pop, @lines ) = sort @lines;

print "$hostname is poping $pop\n";

untie @lines;

print "PID lock file is going to be removed\n";

untie @pid;
unlink $lock or die "Cannot unlink '$lock' $!";

__END__
[download]

Comment on Re: mkfifo/mknode Select or Download Code

Replies are listed 'Best First'.
Re^2: mkfifo/mknode by azaria (Beadle) on Jun 14, 2006 at 12:15 UTC
First thanks for your detailed reply. I used the following code but there is a problem with the flock package - `Usage: Fcntl::constant(name, arg) at Fcntl.pm line 225.` [download] Can you please help ? azaria ------------------------------------------------------- #! /usr/local/bin/perl chomp($hostname=`hostname`); chomp($date = `date \'\+\%y\%m\%d\%H\%M\%S\'`); use warnings; use strict; use Fcntl ':flock'; use Tie::File; my $fifo = "$ENV{HOME}/a_file"; my $lock = "$fifo.lock"; tie( my @pid, 'Tie::File', $lock )->flock( LOCK_EX ) or die "Cannot open '$lock' $!"; @pid = $$; tie( my @lines, 'Tie::File', $fifo )->flock( LOCK_EX ) or die "Cannot open '$fifo' $!"; ( my $pop, @lines ) = sort @lines; print "$hostname is poping $pop\n"; untie @lines; print "PID lock file is going to be removed\n"; untie @pid; unlink $lock or die "Cannot unlink '$lock' $!"; __END__ [download] Janitored by Corion: Added formatting, code tags, as per Writeup Formatting Tips	[reply] [d/l] [select]
Re^3: mkfifo/mknode by jwkrahn (Abbot) on Jun 15, 2006 at 01:16 UTC
I used the following code but there is a problem with the flock package - `Usage: Fcntl::constant(name, arg) at Fcntl.pm line 225.` [download] The Fcntl module that I am using does not have any "usage" messages in it however the Tie::File module does. Which version of the Tie::File module are you using? You can find out like this: `$ perl -MTie::File -le'print $Tie::File::VERSION' 0.97` [download] If the Fcntl module does not work you could go back to using: `my $LOCK_EX = 2;` [download] And change all occurances of LOCK_EX to $LOCK_EX. Also, to get the hostname you could use the Sys::Hostname module: `use Sys::Hostname; my $hostname = hostname;` [download] And to get a formatted date you could use the POSIX module: `use POSIX 'strftime'; my $date = strftime '%y%m%d%H%M%S', localtime;` [download]	[reply] [d/l] [select]