You've been told about the problems with your usage of push and chomp, but I thought you might be interested in seeing a more "Perlish" way of doing this.

#!/usr/bin/perl

use strict;
use warnings;

print 'Enter a list of numbers separated by spaces: ';
chomp(my $input = <STDIN>);
my @arr1 = split /\s+/, $input;

my $count = @arr1;
print "Enter another $count numbers separated by spaces: ";
chomp($input = <STDIN>);

my @arr2 = split /\s+/, $input;

unless (@arr1 == @arr2) {
  die "ERROR: Arrays are different lengths\n";
}

my @sums = map { $arr1[$_] + $arr2[$_] } 0 .. $#arr1;

print "@sums\n";
[download]

Look at the compilation error:

Useless use of push with no values at stuff.pl line 29.
Type of arg 1 to push must be array (not scalar dereference) at stuff.
+pl line 29, near "$sums) "
Execution of stuff.pl aborted due to compilation errors.
[download]

Then look perldoc -f push. You need to give it an array, not a scalar:

  push( @sums, $rray1[$_] + $rray2[$_] );
[download]

As a general rule, you might also consider using use warnings and use strict at the top of your scripts. While this was a simple syntax error, those two modules will help you identify other problems you may encounter.

Your use of push is ...incorrect. See the docs for push() and you'll see that it requires more than one argument.

As for a recommendation on how to add the elements of two arrays, I would do it with List::MoreUtils, using the pairwise() subroutine. Here's from the POD:

pairwise BLOCK ARRAY1 ARRAY2
Evaluates BLOCK for each pair of elements in ARRAY1 and ARRAY2 and returns a new list consisting of BLOCK's return values. The two elements are set to $a and $b. Note that those two are aliases to the original value so changing them will modify the input arrays.

@a = (1 .. 5);
@b = (11 .. 15);
@x = pairwise { $a + $b } @a, @b;   # returns 12, 14, 16, 18, 20
[download]

That's really the right tool for the job, and will lead to clearer code.

Welcome , i just want to say that you should not assign

the chomp() value to the same variable,

chomp() just removes the new line character, we just have to use

  $tdin = <STDIN>;
  chomp($tdin);
  $din = <STDIN>;
  chomp($din);
[download]

my $toolong = "seperated by a space ";
print "Enter the value of the first array $toolong";
$tdin = <STDIN>;
print "Enter the value of the second array $toolong";
$din = <STDIN>;
chomp($tdin);
chomp($din);
#Creates arrays and calculates their length.
@rray1 = split(/ /, $tdin);
@rray2 = split(/ /, $din);

$l1 = $#rray1;
$l2 = $#rray2;

unless($l1 == $l2) {
die(print "ERROR: Arrays are different lengths"); #Error check
}

#Does the adding
for(0..$l1){
    $sum =     $rray1[$_] + $rray2[$_];
    push(@sums,$sum) ;
}

for(0..$l1){
print $sums[$_];}
[download]

see the output
Enter the value of the first array seperated by a space 1 3 5
Enter the value of the second array seperated by a space 2 4 6
3711<sumarat@osmosins.wmindia:>
[download]