Just reading between the lines a little... if you are going to store this stuff in a hash, then I'm guessing that at some later stage you'll want to use the information in the hash. At which time you'll probably need to separate out the different user "attributes" (Real Name, email, etc).

So, why not do this at the start?

Because your data appears to be quite well formed, then using split seems the natural way to go, and create a HoH. Something like this:

#!/usr/bin/perl -w
use strict;

my %user_info;

while (<DATA>) {
    chomp;
    my ($user, $attribs) = $_ =~ m/^(\S+)\s+(.+)$/;

    my ($realname, $email, $foo, $bar, undef)
        = split /\|/, $attribs;

    $user_info{$user}{'Real Name'} = $realname;
    $user_info{$user}{'Email'} = $email;
    $user_info{$user}{'Foo'} = $foo;
    $user_info{$user}{'Bar'} = $bar;
}
__DATA__
username    Real Name|email@gmail.com|2|30|
fred        Fred Bloggs|fbloggs@gmail.com|3|27|
harryp      Harry Potter|harry@gmail.com|5|32|
[download]

You could then do something like this:

foreach my $user (keys %user_info) {
    print "Username:$user Real Name:$user_info{$user}{'Real Name'}\n";
}
[download]

Which would give you:

Username:harryp Real Name:Harry Potter
Username:fred Real Name:Fred Bloggs
Username:username Real Name:Real Name
[download]

Note that the above code could be shortened significantly, but I've deliberately kept it verbose so that it's obvious what's going on. It also doesn't include any sanity-checking on your data, but that could easily be added in.

Hope this helps,
Darren :)

This looks to me like a good opportunity to use a hash slice.

use strict;
use warnings;

my %user_info;

my @fields = qw(name email foo bar);

while (<DATA>) {
    chomp;
    my ($user, $attribs) = split /\s+/, $_, 2;

    my %record;
    @record{@fields} =  split /\|/, $attribs;

    $user_info{$user} = \%record;
}

foreach my $user (keys %user_info) {
    print "Username:$user Real Name:$user_info{$user}{name}\n";
}
[download]

--
<http://dave.org.uk>

"The first rule of Perl club is you do not talk about Perl club."
-- Chip Salzenberg

This should satisfy your requirements, assuming you didn't leave any tricky stuff (like leading whitespaces) out of your OP. Either way, you might want to make sure the regex matched before assigning anything. I assumed that there were a variable number of spaces between the username and the data, since the OP didn't contain a tab.

use warnings;
use strict;

my $line = 'username    Real Name|email@gmail.com|2|30|';

my ( $name, $data ) = $line =~ m/^(\S+)\s+(.+)$/;

print "[$name][$data]";
[download]

HTH

Lots of people seem very keen to give you what you asked for (a regex) without pointing out that this is a perfect opportunity to use split (with its optional third argument).

$data = 'username    Real Name|email@gmail.com|2|30|';
my ($key, $val) = split /\s+/, $data, 2;
$users{$key} = $value;
[download]

That looks like a tab to be so this is pretty easy.

# assuming @users contains your records of the text file
my $userinfo;

foreach my $user (@users)
{
   my ($first, $last) = split(/\t/, $user);
   $userinfo{$first} = $last;
}
[download]