$today = localtime;
sleep(-24*60*60);
$yesterday = localtime;
[download]

Note: Algorithm extrapolated from How Do I Get Tomorrow's Date by Dominus.

You could use Date::Calc like this:

use strict;
use warnings;

use Date::Calc qw/Date_to_Text Add_Delta_Days Today/;

print "Yesterday: ", 
      Date_to_Text( Add_Delta_Days( Today(), -1 ) ), 
      "\n";
[download]

This approach has the advantage of being very easy to read, and less prone to goofing up the math behind subtracting a day from localtime, and it should avoid daylight savings time issues.

The time function gives you the current time in seconds. The previous day is the day which is at least 22 hours before the current time but has a different day date than the current day. 22 hours translates to 22 * 3600 seconds.

So one approach would be not to use localtime without an argument but localtime with a time() value adjusted for the difference you want and then check that the day date is different.

use DateTime;

my $date = DateTime->today;
$date->subtract( days => 1 );

warn "Yesterday's date is " . $date->dmy('-') . "\n";
[download]

#!/usr/bin/perl

use warnings;
use strict;

use Time::Local 'timelocal_nocheck';

sub days_before_now {
    my @date = localtime;
    return timelocal_nocheck(@date[0..2],$date[3]-$_[0], @date[4,5]);
}

print scalar( localtime days_before_now(1)), "\n";
[download]

Subtract a day? Date::Calc exists for this reason.

use Date::Calc qw[Add_Delta_Days Today];
my ($year, $month, $day) = Today();
print "Today is $year-$month-$day; ";

($year, $month, $day) = Add_Delta_Days( Today(), -1 );
print "Yesterday was $year-$month-$day!\n";

__END__
# the above code prints:
Today is 2006-6-30; Yesterday was 2006-6-29!
[download]

This way, you'll take into account all the weirdness of dates (like leap-years, to pick a simple example) without very much work. Good luck!