Update: Ah! Now I understand! How did I miss that?

# @nums = ('2', '22', '222');
my @nums = ($x =~ /\s(\S+)/)[0] =~ /(\d+)/g;
[download]

or

# @nums = ('2', '22', '222');
my @nums = (split(' ', $x, 3))[1] =~ /(\d+)/g;
[download]

I think I understand what is going on in the first of your updated solutions but if I change it to read

my @nums = ($x =~ /\s(\S+)/)[1] =~ /(\d+)/g;
[download]

expecting output of

3
33
[download]

it doesn't work unless I also make the first match global like this

my @nums = ($x =~ /\s(\S+)/g)[1] =~ /(\d+)/g;
[download]

I think this is because the round brackets around the match put the match into list context and the [0] subscript grabs the first elements of the match; however, since the match is non-global there will only ever be one element in the list and trying to get more will not work. If we want a second or subsequent element we must make the match global to capture more than one element.

Have I understood this correctly or am I completely missing the point?

Cheers,

JohnGG

That's exactly it (although there could be 0 elements if the match fails).

my @nums = ($x =~ /\s(\S+)/)[0] =~ /(\d+)/g;
could also be written as
my @nums = ($x =~ /\s(\S+)/ ? $1 : undef) =~ /(\d+)/g;

If you're going to use /g, drop the \s:

# @nums = ('3', '33');
my $word = 2;
my @nums = ($x =~ /(\S+)/g)[$word] =~ /(\d+)/g;
[download]

or use split:

# @nums = ('3', '33');
my $word = 2;
my @nums = (split(' ', $x))[$word] =~ /(\d+)/g;
[download]

This is pulling out all the digits. The OP is just asking for the "digits between the spaces".

my $x = "a1aa11 b2bb22bbb222 c3cc33";
my @nums = $x =~ /\d+/g;
print join(" ", @nums) . "\n";

Output:
1 11 2 22 222 3 33
[download]

Ikegami's answer is pulling out the numbers between the spaces.

my @nums = $x =~ /\d+/g;
[download]

$ perl -le'$x = "a1aa11 b2bb22bbb222 c3cc33"; print for ( $x =~ /\s(\S
++)\s/ )[ 0 ] =~ /\d+/g'
2
22
222
[download]

I want a single regex that grabs all the number characters between the spaces

Extreme regexing? I cannot resist such a question. This ought to do it:

However, if it does not absolutely have to be a single regex, I suspect the maintainer will prefer one of ikegami's solutions. :-)

Update: I've been out-extremed! Not perhaps by the first of ikegami's latter solutions, which after all is straight-forward, and probably as maintainable as mine, but certainly by the second. It took me three attempts just to read it: My eyes glazed over twice!

... what's with the local *nums; though? Yet another update: Ah. Considerate of you. :-)

I hope you're refering to one of these and not one of the following ;)

local *nums;
our @nums;
$x =~ /
   \s  
   (?:
      [^\s\d]*
      (\d+)
      (?{ push(@nums, $1) })
   )*
/x;
[download]

or

local *nums;
our @nums;
$x =~ /
   ^ (?> \S* \s )
   \S*? (?<!\d)
   ( (?> \d+ ) )
   (?{ push(@nums, $1) })
   (?!)
/x;
[download]

... what's with the local *nums; though?

I used package variables because regexps capture. Putting the regexp in a sub would only work once if I had used lexical variables instead of pacakge variables.

our @nums; makes it so I can say @nums instead of @main::nums to refer to the package variable.

local *nums works better than local @nums;. They both ensure that @main::nums has the same value when we're done as it did when we started. In other words, it makes sure we're not trampling over someone else's variables.