You might find the documentation on perldsc helpful to understand the HoH.

foreach my $key( keys %people ) {
    print "\nKey is $key:\n";
    foreach my $element ( keys %{$people{$key}} ) {
        print "\t$element", "= $people{$key}{$element}\n";
    }
}
[download]

my %people = ( 
   Jones => { name => "Alison", age => 15, pet => "dog" },
   Smith => { name => "Tom",    age => 34, pet => "cat" },
   );
foreach my $key (keys %people) {
   print "Key is $key", "value is @{[%{$people{$key}}]}";
   }
[download]

# perl -le'%h=(foo=>1,bar=>'dog');print"%h"'
%h
# perl -le'%h=(foo=>1,bar=>'dog');print"@{[%h]}"'
bar dog foo 1
#
[download]

In such situations, I find it helpful to use Data::Dumper to see what the data really looks like (if necessary), and then break the final dereference into multiple lines for clarity and simplicity, as well as ease-of-use for further operations:

use Data::Dumper;

%people=( 
'Jones'=>{'name'=>'Alison', 'age'=>15, 'pet'=>'dog',},
'Smith'=>{'name'=>'Tom', 'age'=>34, 'pet'=>'cat',});
foreach $person (keys %people)
{
    my $person_attributes = $people{$person};

    # Use Data::Dumper here to be *sure* of the data format
    # of the variable $person_attributes.
    #
    # printf "Person attributes:  %s\n", Dumper(\$person_attributes);

    # Display the values ...
    my @attributes = values %$person_attributes;
    printf "Attributes:  %s\n", join(",", @attributes);

    # ... or make use of one or more attributes ...
    my $age = $person_attributes->{'age'};
    do_something_with_age($age);    # Process this person's age

    # ... or process all of the attributes together
    do_something_with_this_person($person_attributes);
}
[download]

Hashes don't interpolate within quoted strings. You need to do something like this instead:

foreach my $last_name ( keys %people ) {
    print "Last name is $last_name.\n\tDetails are:\n";
    print map { "$_: " . $people->{$last_name}{$_} . "\n\t" }
       keys %{$people->{$last_name}};
    print "\n";
}
[download]

That's untested, so you may have to tinker with it to get your exact desired output, but it should help.

As pointed out by others you don't get anything that is generally very useful when you interpolate a hash reference into a string. However, you can copy hash elements to an array and an array interpolates nicely (for some value of nice):

use strict;
use warnings;

my %people=(
    'Jones'=>{'name'=>'Alison', 'age'=>15, 'pet'=>'dog',},
    'Smith'=>{'name'=>'Tom', 'age'=>34, 'pet'=>'cat',}
    );

for (keys %people) {
    my @values = %{$people{$_}};
    print "@values\n";
}
[download]

Prints:

pet cat name Tom age 34
pet dog name Alison age 15
[download]

I believe it will be helpful for you to browse through our Tutorials; in particular, intro to references and References quick reference will aid your understanding of what is happening in your code.

HTH,