use strict;
my @arr = <STDIN>;
map chomp $_, @arr;
foreach my $i (0..$#arr){
    foreach my $j (0..$#arr){
        print "$arr[$i] $arr[$j]\n" if $i != $j;
    }
}
[download]

Update: If you want to read from list.txt use

foo.pl<list.txt

Actually this one almost gets me all the way there, but ends up printing out a lot of redundancy. I only want any given pair of numbers to appear only ONCE in the output (regardless of the order).

In other words, for 4 numbers, instead of:

1 2
1 3
1 4
2 1
2 3
2 4
3 1
3 2
3 4
4 1
4 2
4 3

...I'd want the output to be:

1 2
1 3
1 4
2 3
2 4
3 4

Is there a way to do this without using the Math::Combinatorics module (I don't have permissions to install Perl modules, and hate having to go through our IT admin, so would like to avoid this if possible)

Ahh, ok, different problem. Just change the inner loop to

    foreach my $j ($i..$#arr){
[download]

awesome! This one works great. Thanks so much!

Are you looking for all unique combinations? If so, here you go...

use strict;
use warnings;

use Math::Combinatorics;




# Get the data file name from command line.
# Output filename is optional.

my( $infile, $outfile ) = @ARGV;

die "No filenames provided.\n" unless defined $infile;
$outfile = ( defined $outfile ) ? $outfile : $infile . '.out';




# Read input data and put it in an array for later use.

open my $in_handle, '<', $infile
    or die "Couldn't open $infile for input.\n$!";

my $dataset_aref;

while ( my $number = <$in_handle> ) {
    chomp $number;
    next unless length $number > 0;
    push @{$dataset_aref}, $number;
}

close $in_handle;





# Create a Math::Combinatorics object.

my $combinat = Math::Combinatorics->new(
    count => 2,
    data  => $dataset_aref,
);





# Open an output file, and print out the combinations.

open my $out_handle, '>', $outfile 
    or die "Couldn't open $outfile for output.\n$!";
    
while ( my @combo = $combinat->next_combination ) {
    print $out_handle "@combo\n";
}

close $out_handle
    or die "Couldn't close $outfile after output.\n$!";
[download]

Usage example:

data.txt should contain a '\n' delimited list of elements. data.out will contain a list of pairings. If you don't specify an output filename one will be chosen for you (the extension '.out' will be added to whatever input filename you specified).

This script uses Math::Combinatorics to find all unique combinations, two at a time. nC2.

A brute force approach, as you indicated, would iterate across the same array in a nested fashion. You would perhaps use code like this (untested):

use strict;
use warnings;
my $fh;
unless (open($fh,"</path/list.txt")) {
  die "Cannot open file: $!\n";
}
my @number_array = ();
while (<$fh>) {
  push @number_array, $_;
}
for (my $i=0;$i<$#number_array;$i++) {
  for (my $j=$i+1;$j<=$#number_array;$j++) {
    print $number_array[$i], "\t", $number_array[$j], "\n";
  }
}
[download]

Update: fixed error in outer loop -- only needs to iterate up to (n-1)th array index.

#!/usr/bin/perl

use warnings;
use strict;

my @ary = (0..5);

print map { "@$_\n" } pairs(@ary);
print "\nCHOOSE:\n";
print map { "@$_\n" } choose(2, @ary);

# hard-coded return of pairs
sub pairs {
    my @result;
    foreach my $i (0..$#_-1) {
        foreach my $j ($i+1..$#_) {
            push @result, [$_[$i], $_[$j]];
        }
    }
    return @result;
}

#more general solution: choose any combinations of k elms from @_:

sub choose {
    no warnings 'recursion';
    my $k = shift;
    my @ary = @_;
    my $n = scalar @ary;
    
    return if ($k > $n) || ($k < 1);
    if ($k == 1) {
        return map { [$_] } @ary;
    }

    my @AoA;
    foreach my $i (0..($n-$k)) {
        push @AoA, map { [$ary[$i], @{$_}] } choose($k-1, @ary[ $i+1..
+$#ary ]);
    }
    return @AoA;
}
[download]

This seems to work.

sed 'N;s/\n/ /' list.txt
[download]

Update: indeed, this is a wrong solution. I didn't read the OP carefully. Sorry.

Update: \n is said to be portable.

thanks but that's not quite what I needed. It has to be "N-by-N", and that simply pairs the 1st with 2nd, 2nd with 3rd, 3rd with 4th, etc. I need to pair the 1st against the 2nd through N. The 2nd against the 3rd through N, etc.