If someone malicious guesses the name of your subroutine, he can execute anything at will. That could be bad.

More likely, if there's a typo, it could call an undefined subroutine, which will have unexpected results. strict mode warns you about typos and other hazardous constructs to reduce these nasty surprises.

The oddly-named Re: use slack; presents one solution. Another would be to call UNIVERSAL::can() on an object, if you're using an object.

Otherwise, you might look through the package symbol table for a named glob, then check it for a code reference and call the code that way. It still requires disabling strict references, but it is a little safer and you can earn a Perl merit badge for knowing how:

sub get_coderef {
    my $subname = shift;
    my $coderef;
    no strict 'refs';
    $coderef = *{"$subname"}{CODE};
    return $coderef if ($coderef and defined(&$coderef));
}
[download]

#!/usr/bin/perl -w

use strict;

sub do_this { print "doing this!\n" }
sub do_that { print "doing that!\n" }

my $code = get_coderef('do_this');
$code->();
$code = get_coderef('do_that');
$code->();
$code = get_coderef('do_nothing');

if (defined($code)) {
    $code->();
} else {
    print "Not defined!\n";
}
[download]

sub mysub { print "mysub $_[0]\n"; }; 
my $s="mysub"; 
&{$s}( "toto");                         # This is what you want
[download]

Note that this is a bad idea though, as it breaks under strict and does not give you any control over which sub is called.

A better way is to use a hash to link a string to a subroutine:

my %h=( mysub1 => \&mysub_1,  # \&mysub_1 is a reference to the subrou
+tine
        mysub2 => \&my_sub_2);
my $s="mysub1";               # or however you get the string 

if( $h{$s})
  { $h{$s}->( "toto"); }     # this is how you call the subroutine wit
+h its arguments
else
  { die "wrong sub called: $s"; }

sub mysub_1 { print "mysub 1 $_[0]\n"; }; 
sub mysub_2 { print "mysub 2 $_[0]\n"; };
[download]

my %CODE = (
   one      => \&one,
   two      => \&two,
   three    => \&three,
   _default => \&not_found,
);

my $input = whatever;

($CODE{$input} || $CODE{_default})->(@arguments);
[download]

#!/usr/bin/perl -w

use strict;

sub filename($){
    print "it worked!\n";
}

my $dbh;
my $filename = 'filename';

no strict 'refs';
&{$filename}($dbh);
use strict 'refs';
[download]

sub mysub($) {
  my $str = shift;
  #code
}

$filename = 'somefile.ext';
open IN, $filename;
$subref = <$filename>;  # maybe it's 'mysub'?
chomp $subref;
no strict 'refs';
no strict 'subs';
&{$subref}( 'text' );
[download]

Jeroen
"We are not alone"(FZ)