my $string = 'aaa:bbb:ccc:ddd:eee:';
my $chunk = '([^:]+:)';

my $colons =()= $string =~ /:/g;
my $regex = $chunk x $colons;
$string =~ /$regex/;
print "$1,$2,$3,$4,$5";
[download]

Splitting on the colon might be your best bet if the nature of your data is field-delimited, but you should also be able to achieve the same with:

  my $src_string = 'aaa:bbb:ccc:ddd:eee:';
  my @results = $src_string =~ /([^:]*):/g;
[download]

Hope this helps,
-v.

That does not work when the string doesn't contain any colon:

my $src_string = 'aaa';
my @results = $src_string =~ /([^:]*):/g;
use Data::Dumper; print Dumper \@results;
__END__
$VAR1 = [];
[download]

--
David Serrano

It seems to me from the OP's description that it will always end in a semi-colon. If not, add it:

my $src_string = 'aaa:bbb:ccc:ddd:eee';
my @results = "$src_string:" =~ /([^:]*):/g;
[download]

Splitting on the colon, you say?

my $src_string = 'aaa:bbb:ccc:ddd:eee:';
my @results = split /:/, $src_string;
pop @results;
[download]

Update: Oops, I missed the last line of the OP. Well, neither solution populates $1, $2, $3, so I guess neither answers the OP.

If you can cope with an array, something as simple as /([^:]+)+/g should do the trick.

my $c='aaa:bbb';
my @arr = $c =~ /[^:]+/g;
use Data::Dumper; print Dumper \@arr;
__END__
$VAR1 = [
          'aaa',
          'bbb'
        ];

---

my $c='aaa:bbb:foo:bar'; 
my @arr = $c =~ /[^:]+/g;
use Data::Dumper; print Dumper \@arr;
__END__
$VAR1 = [
          'aaa',
          'bbb',
          'foo',
          'bar'
        ];
[download]

Update: Simplified the regex, as per Sidhekin suggestion.

When given 'aaa::bbb', your regexp only returns two items.

There was yet only one (kwaping) who correctly answered the OP's question.

Here is my solution to it:

my $string = 'aaa:bbb:ccc:ddd:eee:';
my $regex= $string;
$regex=~ s/[^:]*:/([^:]*:)/g;
$string =~ /$regex/;
print "$1,$2,$3,$4,$5";
[download]

$_ = "aaa:bbb:ccc:ddd:eee:"; @_ = $_ =~ /(.+?:)/g; print "@_"
[download]