my %rooms = (
   townsquare => { 
      name => 'Town Square'
      east => 'store',
   },
   store => {
      name => 'Town Store',
      west => 'townsquare',
   }
);
my %room = ();
# create rooms without connections
while (my ($id,$roominfo) = each %rooms) {
   $room{$id} = Room->new($roominfo->{name}); 
}

# since we now already have all room objects,
# it's easier to add connections to them
while (my ($id, $roominfo) = each %rooms) {
   for (qw(east west north south)) {
     $room{$id}->"add$_"($room{$roominfo->{$_}});
  }
}
[download]

Ofcourse, you could also store just the roomid for connections in the room objects and look them up in the hash when the exitX() methods are called.

Okay, I've never done this in perl. All of my mud coding was ~10 years ago on various LPC / MudOS varients.

However, what we did have was a more abstracted exit system -- after all, who's to say you're not going to way 'northwest' and the like? Or 'up' 'down', etc. (or any other direction 'in', 'out', etc...

sub addexit {
  my ($self, $exit, $direction) = @_;
  $self->{'_exits'}->{$direction} = $exit;
}

sub addhiddenexit {
  my ($self, $exit, $direction) = @_;
  $self->{'_hiddenexists'}->{$direction} = $exit;
}

sub showexits {
  my ($self) = @_;
  my $message = join "\n", 'The following exits are available:',
    map { '    $_\n' } sort keys %{ $self->{'_exits'} };
  return $message;
}

sub exit {
  my ($self, $direction) = @_;
  if ( exists($self->{'_hiddenexits'}->{$direction}) ) {
    return $self->{'_hiddenexits'}->{$direction};
  }
  if ( exists($self->{'_exits'}->{$direction}) ) {
    return $self->{'_exits'}->{$direction};
  }
  return undef;
}
[download]

Now we get to the difficult part ... I didn't like writing rooms the way you're doing it (all in code). The lib we were used filenames for the most part to load objects, but if you specified something of the format 'filename:arg', it would pass the argument to the init?new? function in the file. So I wrote an engine to generate the rooms from various configuration files (partially inspired by one on another mud I had done some coding on). For example, in your case:

# map file
A-B

# key file
KEY : A
NAME : Town Square
KEY : B
NAME : store
[download]

There was then a 'main' file, which inherited from the engine, and contained the following

• where to find the map file
• where to find the 'key' file
• where to find a file that tracked by x/y coordinates
• what file each of the rooms inherited from

The key file could handle naming, items to look at in the room, objects cloned in the room (monsters, removable objects, etc.), and the x/y file could also add extra exits / hidden exits.

The map file use a series of symbols to add exits

- : east / west
| : north/south
\ : nw/se
/ : ne/sw
X : ne/sw/nw/se
^ : north
v : south
> : east
< : west
. : hidden (n/s or e/w, depending on placement)
[download]

Oh -- and a room should probably inherit from 'container' or something similar -- no reason to duplicate the same code for keeping track of people in a room, as for keeping track of items in a bag, items in a person's inventory, etc.

And the exit code is simplified -- you might want to add support for common abbreviations (n:north, nw:northwest, etc.)

Originally I came up with the same basic solution as Joost thinking that the forward references would be a problem, however I still thought it would be nice to have direct access to the objects without an intervening global hash. So I came up the following madness that creates a new singleton class for each room on the fly in the same manner as Re: Creating packages on the fly (and thus comes with all the same caveats). The advantage of using a singleton class is that the problem with the forward references goes away, you just call the constructor whenever you need to and you will either get a new object or get the same one if the constructor had already been called. Obviously creating individual classes for the rooms might not be considered the best design choice by OO purists but that is necessary here for the singleton thing to work.

use strict;
use warnings;
 
my $world = World->new();
my $current = $world->start();
print $current->describe_room();
 
$current = $current->exit("north");
print $current->describe_room();
 
package World;
 
sub new
{
   my ($class) = @_;
 
   my $self = bless {}, $class;
 
 
   while(<main::DATA>)
   {
     chomp;
     my ($room_name,$start,$north,$south,$east,$west) = split /,/;
 
     my $room = $room_name->instance();
     $room->add_exit("north",$north->instance()) if $north;
     $room->add_exit("south",$south->instance()) if $south;
     $room->add_exit("east",$east->instance()) if $east;
     $room->add_exit("west",$west->instance()) if $west;
     $room->description($room_name);
     $self->start($room) if $start;
   }
 
   return $self;
}
 
 
sub start
{
    my ($self, $start ) = @_;
 
    if ( defined $start )
    {
       $self->{_start_room} = $start;
    }
 
    return $self->{_start_room};
}
 
package Room;
 
use base qw(Class::Singleton);
 
my @exits = qw(north south east west);
 
sub add_exit
{
   my ( $self,$direction, $room ) = @_;
 
   $self->{_exits}->{$direction} = $room;
}
 
sub exit
{
   my ($self, $direction ) = @_;
 
   return exists $self->{_exits}->{$direction} ?
                 $self->{_exits}->{$direction} : undef;
}
 
sub exits
{
   my ($self) = @_;
 
   return keys %{$self->{_exits}};
}
 
sub describe_room
{
    my ($self) = @_;
 
    my $description = "You are in the " . $self->description() ."\n";
    $description .= "There are exits:\n";
    foreach my $exit ( $self->exits() )
    {
      $description .= "To the $exit going to the "
                      . $self->exit($exit)->description() . "\n";
    }
 
    return $description;
}
 
sub description
{
   my ( $self, $description ) = @_;
 
   if (defined $description)
   {
      $self->{_description} = $description;
   }
   return $self->{_description};
}
 
sub DESTROY {}
 
package UNIVERSAL;
 
sub DESTROY {}
 
sub AUTOLOAD
{
   my ($class, @args) = @_;
 
   our $AUTOLOAD;
 
   (my $method = $AUTOLOAD) =~ s/.*:://;
 
 
 
   no strict 'refs';
 
   push @{"${class}::ISA"},'Room' ;
 
   $class->$method( @args);
}
 
package main;
 
__END__
Hall,1,Store,,,
Store,0,,Hall,Cupboard,Corridor
Cupboard,0,,,,Store
Corridor,0,,,Store,
[download]

/J\