in reply to Clustering Numbers with Overlapping Members

Assuming no duplicates the following may do what you want:

use warnings;
use strict;

my @nlist = (0,1,2,3,4,5,6,8,10);
my @key_list = ('A'..'Z');
my $tolerance = 1;
my %hoa;

while (@nlist) {
    my $key = shift @key_list;
    my $previous = shift @nlist;
    
    last if ! @nlist;
    
    my $centroid = $nlist[0];
    
    @{$hoa{$key}} = ($previous) if  $previous >= $centroid - $toleranc
+e;
    
    for (@nlist) {
        last if $_ > $centroid + $tolerance;
        push @{$hoa{$key}}, $_;
    }
}

print "$_ => [@{$hoa{$_}}]\n" for sort keys %hoa;

[download]

Prints:

A => [0 1 2]
B => [1 2 3]
C => [2 3 4]
D => [3 4 5]
E => [4 5 6]
F => [5 6]
G => [8]
H => [10]

[download]
DWIM is Perl's answer to Gödel

Replies are listed 'Best First'.
Re^2: Clustering Numbers with Overlapping Members
by Hofmator (Curate) on Aug 07, 2006 at 12:25 UTC

    Your method does not work for $tolerance > 1 - at least not how I understand the question :)

    My solution is based on the OP's statement

    So in principle every element in the array will be a centroid (except the first one, in this case it is 0).
    use warnings;
use strict;
    
my @nlist = (0,1,2,3,4,5,6,8,10);
my @key_list = ('A'..'Z');
my $tolerance = 2;
my %hoa;

for my $i (1..$#nlist) {
    my $key = shift @key_list;
    $hoa{$key} = [grep in_range($nlist[$i], $_), @nlist ];
}

print "$_ => [@{$hoa{$_}}]\n" for sort keys %hoa;

sub in_range
{
    my ($centroid, $testnum) = @_;
    return abs($centroid - $testnum) <= $tolerance;
}

    [download]
    which outputs (with tolerance 2): 
    A => [0 1 2 3]
B => [0 1 2 3 4]
C => [1 2 3 4 5]
D => [2 3 4 5 6]
E => [3 4 5 6]
F => [4 5 6 8]
G => [6 8 10]
H => [8 10]

    [download]

    -- Hofmator

[reply]
[d/l]
[select]

In Section Seekers of Perl Wisdom