I strongly recommend that you use strictures: use strict; use warnings;. They would have told you that the assignment in the conditional expression was likely a bad thing to do. You probably actually want something like:

if ($ARGV[0] eq 'h') {
[download]

Note the use of eq rather than == because you want a string compare rather than a numeric compare.

However a much better way to manage all the command line processing is to use Getopt::Long.

if(@ARGV="h")

A single equals sign is an assignment operator. You're overwriting the value of @ARGV with "h". As "h" is true, that expression will always be true.

You need two equals signs to check equality. But that checks _numeric_ equality, so you actually need "eq"

if(@ARGV eq "h")
[download]

But that's still not right as that compares "h" to the number of elements in @ARGV. If the "h" will always be the first option on the command line, then you could do this:

if ($ARGV[0] eq 'h')
[download]

Or to cover more options, you could use this:

if (grep { $_ eq 'h' } @ARGV)
[download]

But really, you should look at one of the command line option processing modules like Getopt::Std or Getopt::Long.

As "h" is true that expression will always be true.

To be pedantic, it is not because "h" is true that the expression is true, otherwise

if ( @ARGV = 0 )

would evaulate to false, which it doesn't.

Rather, if my reading of perlop is correct, it is because the assignment operator returns true (or more strictly, the number of elements assigned to @ARGV):

my $return = @ARGV = ( 1, 2, 3 );
print $return;
[download]

prints 3.

Update: fixed typos in text.

Your code

if (@ARGV="h") {
    ...
};
[download]

is not checking whether @ARGV contains the string "h", it assigns @ARGV = "h";. You should look at Getopt::Long and The Dynamic Duo --or-- Holy Getopt::Long, Pod::UsageMan! how to best implement command line parsing.

The two obvious issues are:

1. @ARGV is an array, not a scalar. You probably want to be comparing the first item in it, not the whole thing.
2. '=' is the assignment operator, you want to string equality operator 'eq'

(And you're also failing to use strict and warnings)

Hi, If I understood your question correctly then try like this,

use strict;
use warnings;
use Win32;
use Getopt::Std;
my %opts;

getopts("h", \%opts);

help() if $opts{h};


sub help
{
    Win32::MsgBox("Help Content", 32, "Help");
    exit;
}
[download]

Updated : Thanks davorg.

for a long time, Getopt::Std has supported an interface which doesn't require the use of package variables. You can pass in a reference to a hash and that hash will be populated with the options.

use Getopt::Std;

my %opts;

getopts('h', \%opts);

help() if $opts{h};
[download]

I think that's a much nicer interface.

Also, I think your call to getopts uses the Getopt::Long interface, not the Getopt::Std one. Getopt::Std only supports single letter options.

--
<http://dave.org.uk>

"The first rule of Perl club is you do not talk about Perl club."
-- Chip Salzenberg