my $cnt = $str =~ tr/1//;
[download]

my %char_cnt;
++$char_cnt{$_} for split //, $str;
[download]

use strict;
use warnings;
my $a = '12345678901';

# Create a hash which has a count of the number
# of times a character appears in the string.
my %tally;
$tally{$_}++ for split '', $a;

#
# Find hash keys that only have 1 match
#
my @unique = grep {$tally{$_} == 1} keys %tally;
print "Unique keys:\n";
print "$_\n" for sort @unique;
[download]

  if ($tally{2} == 1) {
     print "2 is unique\n";
  }
[download]

my $a = '12345678901';
my $cnt = $a =~ tr/1//;

#In this case $cnt = 2, which means it is not unique
[download]

my $string = '123456789012345';

my %counts ;

$counts{ $_ }++ for split //, $string;

foreach my $char ( keys %counts ){
    if( $counts{ $char } > 1 ){
        print "$char is not unique in $string\n";
    }else{
        print "$char is unique in $string\n";
    }
}
[download]

Or if the question you want to answer is "Is there a character that is repeated within the string?" then you can:

print "'$1' repeated\n" if "12345617890" =~ /(.).*?\1/;
[download]

Prints:

'1' repeated
[download]

If you want to determine if a given character is unique then you could use

if( $var =~ m[1] and $var !~ m[1.*1] ) {
   ## $var contains exactly one '1' character.
}
[download]

Alternatively, if you want to know if the string contains no duplicates of any character then

if( $var !~ m[(.).*\1] ) {
    ## $var contains no duplicate characters
}
[download]

Similar questions have been asked quite a few times. (More bluntly, Try a [id://Super Search|little research] first.).

> where @singletons is a list of the elements in @string which occur only once. Note, however, that this operates on lists, not strings, so you'll have to split the string.

use strict;use warnings;  # because it's a really good idea

my @string = split(//, 'aabbccddeeffgghhi');

my %count;

foreach(@string) {
    $count{$_} ++;
}

foreach (keys(%count)) {
    print "$_ is unique\n" if $count{$_} == 1;
}
[download]

I'm quite sure some of the regex gurus can do it with a single regex; I tend more to the "brute force and ignorance"™ school of programming than the "subtle and brilliant" school.

added in another update

As Hofmator pointed out, I screwed up: uniq doesn't return a list of elements that occur once in the original list; it returns a list with duplicates stripped out. That's why I've struck out a much of this post.

I knew that somebody would find a one-line solution.

my @string = qw(a a a a b b b c d e f q q q r r r);
my @singletons = uniq(@string);
[download]

where @singletons is a list of the elements in @string which occur only once.

This is not true, uniq removes duplicates from an array. From the doc:

uniq LIST
Returns a new list by stripping duplicate values in
LIST. The order of elements in the returned list is
the same as in LIST. In scalar context, returns the
number of unique elements in LIST.

my @x = uniq 1, 1, 2, 2, 3, 5, 3, 4; # returns 1 2 3 5 4
[download]

-- Hofmator

use strict;
use warnings;

my $str = q{abcdceefghfty};

for my $ch (qw(a b c d e f g))
{
    print qq{"$ch" Unique in "$str"\n}
       if $str !~ m{($ch)(?=.*\1)};
}
[download]

which produces

"a" Unique in "abcdceefghfty"
"b" Unique in "abcdceefghfty"
"d" Unique in "abcdceefghfty"
"g" Unique in "abcdceefghfty"
[download]

Cheers,

JohnGG

Update: The above approach is flawed in that testing for a character that doesn't occur in the string at all would still succeed and show as unique. This is because testing that the string doesn't match multiple characters is also true if there are no characters.

The amended script below changes by looking for positive matches of a single character. It is a touch more complex because of the need to interpolate the character being sought into a negated character class, hence the qr{...}. Looking for a hard-coded character is simpler, e.g. to check that "c" was unique, $str =~ m{\A[^c]*(c)(?!.*\1)} would work. Here's the amended script.

use strict;
use warnings;

my $str = q{abcdceefghfty};

for my $ch (q{a} .. q{z})
{
    my $matchTxt
       = q {\A}
       . qq{[^$ch]*($ch)}
       . q {(?!.*\1)};
    my $rxUniq = qr{$matchTxt};
    print qq{"$ch" unique in "$str"\n}
       if $str =~ $rxUniq;
}
[download]